Excel Ole Objekt noch Prozessliste beenden, nachdem

Question

Ich habe diesen Code:

function XlsToStringGrid(AGrid: TStringGrid; AXLSFile: string): Boolean; 
const 
    xlCellTypeLastCell = $0000000B; 
var 
    XLApp, Sheet: OLEVariant; 
    RangeMatrix: Variant; 
    x, y, k, r: Integer; 
begin 
    Result:=False; 
    //Cria Excel- OLE Object 
    XLApp:=CreateOleObject('Excel.Application'); 
    try 

     XLApp.Visible:=False; 

     XLApp.Workbooks.Open(AXLSFile); 
     Sheet:=XLApp.Workbooks[ExtractFileName(AXLSFile)].WorkSheets[1]; 
     Sheet.Cells.SpecialCells(xlCellTypeLastCell, EmptyParam).Activate; 

     x:=XLApp.ActiveCell.Row; 

     y:=XLApp.ActiveCell.Column; 

     AGrid.RowCount:=x; 
     AGrid.ColCount:=y; 

     RangeMatrix:=XLApp.Range['A1', XLApp.Cells.Item[X, Y]].Value; 

     k:=1; 
     repeat 
      for r:=1 to y do 
       AGrid.Cells[(r - 1),(k - 1)]:=RangeMatrix[K, R]; 
      Inc(k,1); 
     until k > x; 
     RangeMatrix:=Unassigned; 
     Result:=True; 

    finally 

     if not VarIsEmpty(XLApp) then 
     begin 
      Sheet:=Unassigned; 
      XLApp.Workbooks[ExtractFileName(AXLSFile)].Close; 
      XLApp.Quit; 
      XLAPP:=Unassigned; 
     end; 
     try freeandnil(XLAPP) except; end; 
     try freeandnil(Sheet) except; end; 
    end; 
end; 

aber nachdem er mit dem Befehl Beenden beenden, bleibt der Prozess noch in der Liste, Überlegungen: Ich Suche durchgeführt und verstanden, dass, wenn es Ein referenziertes Objekt bleibt in der Liste, aber ich glaube, dass ich alles freigegeben habe.

Answer 1

Der Befehl Quit() von Excel ist nicht synchron. Es kann eine Weile dauern, bis der Prozess tatsächlich beendet wird.

Und ja, Sie haben möglicherweise aktive Objektreferenzen. Sie löschen RangeMatrix nicht, wenn in Ihrer repeat Schleife eine Ausnahme auftritt, so dass es möglicherweise nicht gelöscht wird, bis XlsToStringGrid() beendet wird. Sie sollten mehrere try/finally Blöcke verwenden, einen für jedes Objekt.

Und bitte, rufen Sie nicht auf (Ole)Variant Variablen! Es funktioniert nur auf TObject Zeiger.

Versuchen Sie stattdessen:

function XlsToStringGrid(AGrid: TStringGrid; AXLSFile: string): Boolean; 
const 
    xlCellTypeLastCell = $0000000B; 
var 
    XLApp, WorkBook, Sheet: OLEVariant; 
    RangeMatrix: Variant; 
    x, y, k, r: Integer; 
begin 
    Result := False; 

    XLApp := CreateOleObject('Excel.Application'); 
    try 
    XLApp.Visible := False; 

    XLApp.Workbooks.Open(AXLSFile); 
    try 
     WorkBook := XLApp.Workbooks[ExtractFileName(AXLSFile)]; 
     try 
     Sheet := WorkBook.WorkSheets[1]; 
     try 
      Sheet.Cells.SpecialCells(xlCellTypeLastCell, EmptyParam).Activate; 

      x := XLApp.ActiveCell.Row; 
      y := XLApp.ActiveCell.Column; 

      AGrid.RowCount := x; 
      AGrid.ColCount := y; 

      RangeMatrix := XLApp.Range['A1', XLApp.Cells.Item[X, Y]].Value; 
      try  
      k := 1; 
      repeat 
       for r := 1 to y do 
       AGrid.Cells[(r - 1),(k - 1)] := RangeMatrix[K, R]; 
       Inc(k); 
      until k > x; 
      finally 
      RangeMatrix := Unassigned; 
      end; 

      Result := True; 
     finally 
      Sheet := Unassigned; 
     end; 
     finally 
     WorkBook.Close; 
     WorkBook := Unassigned; 
     end; 
    finally 
     XLApp.Workbooks.Close; 
    end; 
    finally 
    XLApp.Quit; 
    XLAPP := Unassigned; 
    end; 
end;