„war zu diesem Zeitpunkt unerwartet“ geschieht nur auf einzelnen Computer

Question

Wir haben ein Problem mit der folgenden Befehlszeile bekam (es in einer Batch-Datei ausgeführt wird):

for /f tokens^=3^ delims^=.-_^" %%j in ('cmd /c "%JAVA_HOME%\bin\java.exe" -version 2^>^&1 ^| findstr /i "version"') do set "jver=%%j" 

Wenn wir diese Linie ausführen, erhalten wir die Java-Version. Dies funktioniert jedes Mal, aber jetzt haben wir einen Computer hier unter Windows 10, die das Skript nicht ausführen kann und nicht auf dieser Linie und sagt:

8 was unexpected at this time 

Also gehe ich davon aus dem Skript in der Lage ist, die 1.8.0_101 Java-Version zu lesen String aber irgendwie scheitert. Die Variable jver wird nur einmal verwendet:

if %jver% LSS 8 (
    goto :jdk_wrong_version 
) 

Weiß jemand, warum dieses seltsame Verhalten auftritt? Weil fast alle Maschinen kein Problem mit diesem Befehl haben. Die Ausgabe, wenn wir Java-Version ausführen, scheint in Ordnung.

EDIT:

Folgende Zeilen zu Beginn ausgeführt werden (also wir überprüfen, ob JAVA_HOME verfügbar ist):

"%JAVA_HOME%\bin\java.exe" -version 1> NUL 2> NUL 
if not %errorLevel%==0 goto :java_not_found 

Also das ganze Skript wie folgt aussieht:

"%JAVA_HOME%\bin\java.exe" -version 1> NUL 2> NUL 
if not %errorLevel%==0 goto :java_not_found 

for /f tokens^=3^ delims^=.-_^" %%j in ('cmd /c "%JAVA_HOME%\bin\java.exe" -version 2^>^&1 ^| findstr /i "version"') do set "jver=%%j" 

if %jver% LSS 8 (
    goto :jdk_wrong_version 
) 

Answer 1

I vermuten, dass "%JAVA_HOME%\bin\java.exe" nicht existiert - möglicherweise wurde JAVA_HOME nicht als Umgebungsvariable festgelegt.

Answer 2

Ich schlage vor, den folgenden Batch-Code zu verwenden, sicher auf der Bestimmung Version von Java jeden möglichen Fehler zu erkennen:

@echo off 
setlocal EnableExtensions DisableDelayedExpansion 
if not defined JAVA_HOME (
    echo Environment variable JAVA_HOME is not defined. 
    goto :EOF 
) 
if not exist "%JAVA_HOME%\bin\java.exe" (
    echo File "%JAVA_HOME%\bin\java.exe" does not exist. 
    goto :EOF 
) 
for /F "tokens=1-3" %%A in ('"%JAVA_HOME%\bin\java.exe" -version 2^>^&1') do (
    if /I "%%A %%B" == "java version" (
     set "JavaVersion=%%~C" 
     goto EvaluateVersion 
    ) 
) 
echo Failed to determine version of installed Java. 
goto :EOF 

:EvaluateVersion 
echo Java version is: %JavaVersion% 
for /F "tokens=2 delims=." %%I in ("%JavaVersion%") do set "jver=%%I" 
echo Main version is: %jver% 
rem More batch code. 
endlocal 

Java druckt die Version STDERR statt Griff STDOUT das der Grund ist, zu handhaben für 2>&1 mit der Flucht der Operatoren > und & mit ^ in der Befehlszeile von FÜR ausgeführt.

Wenn die Java-Version erfolgreich ermittelt werden kann, ist der Ausgang so etwas wie:

Java version is: 1.7.0_55 
Main version is: 7