Binäre Operationen auf Erlang-Binärdateien?

Question

Was ist der beste Weg, um folgendes zu tun? Binär -> Liste -> Binär scheint unnötig.

binary_and(A, B) -> 
    A2 = binary_to_list(A), 
    B2 = binary_to_list(B), 
    list_to_binary([U band V || {U, V} <- lists:zip(A2, B2)]). 

Answer 1

Wenn Sie nicht auf Leistung achten, ist Ihr Code absolut in Ordnung. Ansonsten kannst du etwas anderes machen.

Zum Beispiel unterstützt Erlang Ganze Zahlen beliebiger Größe:

binary_and(A, B) -> 
    Size = bit_size(A), 
    <<X:Size>> = A, 
    <<Y:Size>> = B, 
    <<(X band Y):Size>>. 

Oder Sie können Ihre eigenen binären zip Routine Handwerk:

binary_and(A,B) -> binary_and(A, B, <<>>). 

binary_and(<<A:8, RestA/bytes>>, <<B:8, RestB/bytes>>, Acc) -> 
    binary_add(RestA, RestB, <<Acc/bytes, (A band B):8>>); 
binary_and(<<>>, <<>>, Result) -> Result. 

Oder optimierte Version:

binary_and(A,B) -> binary_and(A, B, <<>>). 

binary_and(<<A:64, RestA/bytes>>, <<B:64, RestB/bytes>>, Acc) -> 
    binary_add(RestA, RestB, <<Acc/bytes, (A band B):64>>); 
binary_and(<<A:8, RestA/bytes>>, <<B:8, RestB/bytes>>, Acc) -> 
    binary_add(RestA, RestB, <<Acc/bytes, (A band B):8>>); 
binary_and(<<>>, <<>>, Result) -> Result. 

oder mehr anspruchsvolle

binary_and(A,B) -> binary_and({A, B}, 0, <<>>). 

binary_and(Bins, Index, Acc) -> 
    case Bins of 
    {<<_:Index/bytes, A:64, _/bytes>>, <<_:Index/bytes, B:64, _/bytes>>} -> 
     binary_add(Bins, Index+8, <<Acc/bytes, (A band B):64>>); 
    {<<_:Index/bytes, A:8, _/bytes>>, <<_:Index/bytes, B:8, _/bytes>>} -> 
     binary_add(Bins, Index+1, <<Acc/bytes, (A band B):8>>); 
    {<<_:Index/bytes>>, <<_:Index/bytes>>} -> Acc 
    end. 

Wie auch immer Sie messen müssen, wenn Sie wirklich an Leistung interessiert sind. Vielleicht ist der Erste der Schnellste für Ihre Zwecke.

Answer 2

Wenn Sie die Macht der dunklen Seite sehen wollen ...

binary_and(A, B) -> 
    Size = erlang:byte_size(A), 
    Size = erlang:byte_size(B), 
    Res = hipe_bifs:bytearray(Size, 0), 
    binary_and(Res, A, B, 0, Size). 

binary_and(Res, _A, _B, Size, Size) -> 
    Res. 

binary_and(Res, A, B, N, Size) -> 
    Bin = hipe_bifs:bytearray_sub(A, N) band hipe_bifs:bytearray_sub(B,N), 
    hipe_bifs:bytearray_update(Res, N, Bin), 
    binary_and(Res, A, B, N+1, Size).