VBScript WQL Sort Result Set?

Question

Anscheinend enthält WQL keine ORDER BY Klausel. Gibt es eine Möglichkeit, die Ergebnismenge basierend auf einer der Spalten zu sortieren? Zum Beispiel:

Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2") 
sSQL = "Select Time,Source,Event,CategoryNum,Category,TypeNum,Type,User,ComputerName,Insertion1,Insertion2,Data from Win32_NTLogEvent Where Logfile = 'System' and SourceName = 'Service Control Manager'" 
Set resultSet = objWMIService.ExecQuery (sSQL) 
For Each objEvent In resultSet 
    ... 
Next 

Gibt es eine Möglichkeit resultSet durch die Time Spalte zu sortieren?

Answer 1

WQL hat in der Tat keine Sortierklausel, so dass eine Sortierung direkt in der Abfrage nicht möglich ist. Was Sie tun können, ist die zurückgegebenen Daten in einem disconnected recordset setzen und dann den Re-Cord sortieren:

Set DataList = CreateObject("ADOR.Recordset") 
DataList.Fields.Append "Time", 7 
DataList.Fields.Append "Source", 200, 255 
DataList.Fields.Append "Event", 3 
... 
DataList.Open 

Set wmi = GetObject("winmgmts:{impersonationLevel=impersonate}!//./root/cimv2") 
qry = "SELECT Time,Source,Event,CategoryNum,Category,TypeNum,Type,User,ComputerName,Insertion1,Insertion2,Data " & _ 
     "FROM Win32_NTLogEvent " & _ 
     "WHERE Logfile='System' AND SourceName='Service Control Manager'" 

For Each evt In wmi.ExecQuery(qry) 
    DataList.AddNew 
    DataList("Time") = evt.Time 
    DataList("Source") = evt.Source 
    DataList("Event") = evt.Event 
    ... 
    DataList.Update 
Next 

DataList.Sort = "Time" 
DataList.MoveFirst 
Do Until DataList.EOF 
    WScript.Echo DataList.Fields.Item("Time") & vbTab & _ 
     DataList.Fields.Item("Event") 
    DataList.MoveNext 
Loop 

die data type der Felder nach Bedarf anpassen.