XSLT Transformation basierend auf ungeraden und geraden

Question

Ich möchte unter Komma getrennte Liste zu unter Ausgabe basierend auf ungerade und gerade Position durch XSLT konvertieren.

Eingang -

field1,value1,field2,value2,field3,value3 

Output-

<root> 
<field1>value1</field1> 
<field2>value2</field2> 
<field3>value3</field3> 
</root> 

Vielen Dank im Voraus.

Grüße Nilay

Answer 1

Sie eine rekursive Template-Funktionen aufrufen, ohne Erweiterung verwenden könnten ...

XSLT 1,0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:param name="input" select="'field1,value1,field2,value2,field3,value3'"/> 

    <xsl:template match="/"> 
    <root> 
     <xsl:call-template name="process"> 
     <xsl:with-param name="toProcess" select="$input"/> 
     </xsl:call-template> 
    </root> 
    </xsl:template> 

    <xsl:template name="process"> 
    <xsl:param name="toProcess"/> 
    <xsl:variable name="name" select="normalize-space(substring-before($toProcess,','))"/> 
    <xsl:variable name="value" select="normalize-space(substring-before(
     concat(substring-after($toProcess,','),',') 
     ,','))"/> 
    <xsl:variable name="remaining" select="substring-after(
     substring-after($toProcess,',') 
     ,',')"/> 
    <xsl:element name="{$name}"> 
     <xsl:value-of select="$value"/> 
    </xsl:element> 
    <xsl:if test="string($remaining)"> 
     <xsl:call-template name="process"> 
     <xsl:with-param name="toProcess" select="$remaining"/> 
     </xsl:call-template> 
    </xsl:if> 
    </xsl:template> 

</xsl:stylesheet> 

Output (mit einem beliebigen wohlgeformte XML Eingabe.)

<root> 
    <field1>value1</field1> 
    <field2>value2</field2> 
    <field3>value3</field3> 
</root>