Bessere Möglichkeit, findstr zu verwenden, um Paketverlust zu erhalten, Batch

Question

Suchen Sie nach findstr, um es zu finden, "0% Verlust" nach einem Ping-Befehl. Vielleicht ein Array von etwas bis zu "50% Verlust".

Dies ist zum Überprüfen und Sicherstellen, dass eine Verbindung zum Internet zu 100% hergestellt ist, bevor Sie etwas online starten.

Derzeit ist es strukturiert:

ping %ip% -n 3 -w 3000 | findstr "0% loss" 
pause 
goto Starting 

Es ist derzeit findstr ignorieren ist und egal, was es ablehnt, zu finden, was ich suche

Ideal wäre es fließen wie:

ping %ip% -n 3 -w 3000 | findstr "0% loss" || goto Echo 
pause 
goto Starting 
:echo 
Could not find "0% loss" 
pause 

Und ich habe es versucht, es wird Echo, aber sogar mit 100% Verbindung, so dass es eindeutig nicht funktioniert, wie ich es gerne würde.

Gibt es eine bessere Möglichkeit,% Paketverlust zu finden?

Oder

Gibt es eine bessere Art und Weise Internetverbindung zu testen, da ping funktioniert nicht, wenn ein Gerät vollständig offline ist.

Answer 1

Der Suchbegriff, nach dem Sie suchen, ist zu breit. Wenn Sie findstr für "0% Verlust" prüfen, nehmen Sie versehentlich auch "10 0% Verlust" auf. Glücklicherweise setzt ping den Paketverlust in Klammern, sodass Sie einfach die öffnende Klammer in die Suchzeichenfolge einfügen können.

@echo off 
title Restart 
color 0A 
cls 

:start 
Cls 
set ip=www.google.com 

:Pingcheck 
echo Checking ping.. 
timeout /t 3 
ping %ip% -n 5 -w 3000 | findstr /C:"(0% loss" || goto Loss 
pause 

:NoLoss 
echo We found 0 packet loss, at %ip% on %date% at %time% 
pause 
goto start 

:Loss 
echo We found some packet loss. 
pause 

Ich habe mich verändert auch den Namen des :Echo Label weil echo bereits ein Befehl ist und es auch ein Label verwirrend wäre sein.

Answer 2

Sie können den Ping-Status auch mit wmi überprüfen. Der Vorteil dieser Methode ist, dass sie beim ersten Fehler goto :fail ist und nicht ihre verlorene Ursache für den Abschluss von 5 Ping-Versuchen fortsetzt, während sie gleichzeitig eine einfache Möglichkeit bietet, die durchschnittliche Antwortzeit beizubehalten. Es verwendet set /a, um zu überprüfen, ob das Ergebnis der WMI-Abfrage einen numerischen Wert enthält. Wenn ja, pass auf. Wenn nicht, scheitern.

@echo off & setlocal 

set "host=www.google.com" 

echo Pinging %host%... 

for /L %%I in (1,1,5) do (
    for /f "delims=" %%x in (
     'wmic path win32_pingstatus where "address='%host%' and timeout=3000"^ 
     get ResponseTime /value ^| find "="' 
    ) do (
     2>NUL set /a "%%x, avg += ResponseTime" || goto fail 
    ) 
) 

set /a "avg /= 5" 
echo 0%% packet loss. Woo. Average response time was %avg%ms. 
exit /b 

:fail 
echo Aw snap. Packet loss.