Wie macht man zwei in QML verknüpfte Scrollviews?

Question

Ich möchte eine Header-feste Tabelle erstellen. Die Idee, die ich jetzt habe, verwendet zwei ScrollView, eine für den Header (RowLayout), eine für den Körper (GridLayout). Gibt es eine einfache Möglichkeit, diese beiden in horizontaler Richtung zu verknüpfen, so dass ein Scroll, der andere Scroll gleich?

Answer 1

Ich weiß nicht, wie es zu tun mit dem low-performingQtQuick.Controls 1.x, aber die QtQuick.Controls 2.0ScrollBar hat eine Eigenschaft position.

Also hier ist der Trick, zwei ScrollBar s, eins für jedes Element zu scrollen, und binden Sie die Position von jedem an die Position zu dem anderen.

ApplicationWindow { 
    visible: true 
    width: 300 
    height: 120 
    title: qsTr("Hello World") 


    Column { 
     anchors.fill: parent 
     Flickable { 
      id: flick1 
      width: parent.width 
      height: parent.height/2 
      contentHeight: 2 * height 
      contentWidth: 2 * width 
      Item { 
       anchors.fill: parent 
       Rectangle { 
        width: parent.height 
        height: parent.width 
        anchors.centerIn: parent 
        rotation: 90 

        gradient: Gradient { 
         GradientStop { position: 1; color: 'black' } 
         GradientStop { position: 0; color: 'white' } 
        } 
       } 
      } 

      ScrollBar.horizontal: scrl1 
     } 
     Flickable { 
      id: flick2 
      width: parent.width 
      height: parent.height/2 
      contentHeight: 2 * height 
      contentWidth: 2 * width 
      clip: true 

      Item { 
       anchors.fill: parent 
       Rectangle { 
        width: parent.height 
        height: parent.width 
        anchors.centerIn: parent 
        rotation: 90 

        gradient: Gradient { 
         GradientStop { position: 0; color: 'black' } 
         GradientStop { position: 1; color: 'white' } 
        } 
       } 
      } 

      ScrollBar.horizontal: scrl2 
     } 
    } 


    ScrollBar { 
     id: scrl1 
     orientation: Qt.Horizontal 
    } 

    ScrollBar { 
     id: scrl2 
     orientation: Qt.Horizontal 
    } 

    Binding { 
     target: scrl2 
     property: 'position' 
     value: scrl1.position 
    } 
    Binding { 
     target: scrl1 
     property: 'position' 
     value: scrl2.position 
    } 
} 

Wie ScrollBar s fast alles befestigen, die Sie in der Antwort auf diese Frage finden. Ich arbeite nicht mit Layouts so, ich kann nicht genauer auf sie sein.

how to create a scrollbar for rectangle in QML