Wie Array-Werte zu Spalte mit Excel VBA

Question

hinzufügen Ich verwende unter VBA-Code, ich habe mehrere Spalten für Beispiel habe ich wenige zur Verfügung gestellt. Alles, was ich versuche, ist, wenn ich versuche, die Änderungen denselben Wert auf die gelöschten Spaltenüberschriften wiederherzustellen. Unten Code funktioniert gut, wenn ich Änderungen an den Bereich "A1" vornehmen, aber wenn ich andere Änderungen als "A1", Code dauert zu viel Zeit abgeschlossen und es ist zu oft Schleifen.

Private Sub Worksheet_Change(ByVal Target As Range) 
Dim headers() As Variant 
If Range("A1").Value <> "FIRST" Or Range("B1").Value <> "Second" Or Range("C1").Value <> "Third" Then 
headers() = Array("FIRST", "Second", "Third") 
With Sheets("Sheet1") 
For i = LBound(headers()) To UBound(headers()) 
.Cells(1, 1 + i).Value = headers(i) 
Next i 
.Rows(1).Font.Bold = True 
End With 
End If 

============================== Bitte mir helfen, dieses Problem zu beheben, schätzen Ihre Hilfe voraus.

Answer 1

Sie haben Ereignisse der Sperrung kümmern, bevor Sie die Werte ändern. Versuchen Sie den folgenden Code:

Private Sub Worksheet_Change(ByVal Target As Range) 
Dim Header As Variant 
    If Application.Intersect(Target, Target.Parent.Range("A1:C1")) Is Nothing Then Exit Sub 
    Application.EnableEvents = False 
    Header = Array("FIRST", "Second", "Third") 
    Target.Parent.Range("A1:C1").Value = Header 
    Application.EnableEvents = True 
End Sub 

Answer 2

Das Problem ist, dass die Wertänderung auf .Cells(1, 1 + i).Value = headers(i) das Ereignis selbst auslöst. Du gehst im Grunde in eine endlose Ausführungskette wie diese.

Sie sollten entweder die Ereignisse während der Ausführung dieses Makros deaktivieren oder eine Überprüfung für jede Kopfzeile durchführen.

Die einfachste Lösung:

Option Explicit 
Private Sub Worksheet_Change(ByVal Target As Range) 
Dim headers() As Variant 
Dim i As Integer 

Application.EnableEvents = False 'This fixes your issue. 

If Range("A1").Value <> "FIRST" Or Range("B1").Value <> "Second" Or Range("C1").Value <> "Third" Then 
    headers() = Array("FIRST", "Second", "Third") 
    With Sheets("Sheet1") 
     For i = LBound(headers()) To UBound(headers()) 
      .Cells(1, 1 + i).Value = headers(i) 
     Next i 
     .Rows(1).Font.Bold = True 
    End With 
End If 

Application.EnableEvents = True 
End Sub