Wie kann ich eine Liste von DFMs erstellen, die in einem Projekt verwendet werden?

Question

Ich möchte ein Delphi-Plug-in erstellen, das alle DFMs im aktuellen Projekt auflisten kann.

Gibt es eine Möglichkeit, eine Liste aller im aktuellen Projekt verknüpften DFM-Dateien (und deren Pfade) zu erhalten?

Wenn alle DFMs aufgelistet sind, können Dinge über das Projekt extrahiert werden, und möglicherweise werden nur Suchen in den aktuellen Projekt-DFMs durchgeführt, z. B. die Analyse der DFMs nach einer Eigenschaft.

Ich habe this question gefunden, die beantwortet wurde, aber nicht adressiert, wie man zu den DFMs kommt. Und diese Lösung erfordert das Ändern jeder .pas-Datei im Repository und gibt eine Lösung zur Laufzeit. Meine Frage dreht sich um Design-Zeit.

Answer 1

Hier ist ein kurzes Beispiel mit OpenTools API. Fügen Sie dieses Gerät einem neuen Design-only-Paket hinzu, fügen Sie designide und vcl dem requires-Klausel hinzu. Kompilieren und installieren Sie das Paket. Es wird ein Menüeintrag "DFM-Liste" unter Hilfe \ Hilfe-Assistenten hinzugefügt. Wenn Sie darauf klicken, wird die folgende Methode Execute aufgerufen.

unit ListDfmExample; 

interface 

uses 
    Windows, VCL.Forms, VCL.Dialogs, Classes, SysUtils, ToolsAPI; 

type 
    TListDfmWizard = class(TNotifierObject, IOTAWizard, IOTAMenuWizard) 
    { IOTAWizard } 
    function GetIDString: string; 
    function GetName: string; 
    function GetState: TWizardState; 
    procedure Execute; 
    { IOTAMenuWizard } 
    function GetMenuText: string; 
    end; 

implementation 

function TListDfmWizard.GetIDString: string; 
begin 
    Result := 'TOndrej.ListDfmWizard'; 
end; 

function TListDfmWizard.GetName: string; 
begin 
    Result := 'ListDfm'; 
end; 

function TListDfmWizard.GetState: TWizardState; 
begin 
    Result := [wsEnabled]; 
end; 

procedure TListDfmWizard.Execute; 
var 
    Project: IOTAProject; 
    I, J: Integer; 
    ModuleInfo: IOTAModuleInfo; 
    Module: IOTAModule; 
    Editor: IOTAEditor; 
    FormEditor: IOTAFormEditor; 
    List: TStringList; 
begin 
    Project := GetActiveProject; 
    if not Assigned(Project) then 
    Exit; 

    List := TStringList.Create; 
    try 
    for I := 0 to Project.GetModuleCount - 1 do 
    begin 
     ModuleInfo := Project.GetModule(I); 
     if ModuleInfo.FormName <> '' then 
     begin 
     Module := ModuleInfo.OpenModule; 
     for J := 0 to Module.ModuleFileCount - 1 do 
     begin 
      Editor := Module.ModuleFileEditors[J]; 
      if Supports(Editor, IOTAFormEditor, FormEditor) then 
      List.Add(FormEditor.FileName); 
     end; 
     end; 
    end; 

    ShowMessage(List.Text); 
    finally 
    List.Free; 
    end; 
end; 

function TListDfmWizard.GetMenuText: string; 
begin 
    Result := 'List DFM'; 
end; 

initialization 
    RegisterPackageWizard(TListDfmWizard.Create); 

end.