gnuplot: single-Palette in Multiplot Modus

Question

Plotten Ich möchte etwas Hilfe zu folgendem Thema fragen:

Der folgende Code 3 Parzellen (3 Reihen, 1 Spalte) erzeugt auf der gleichen Seite:

set terminal postscript color 
set output "test.ps" 
file="test.dat" 

set palette rgb 33,13,10 
set cblabel "[km]" 
set cbtics 2.5, 5, 20 format "%.0f" 

set lmargin at screen 0.08 
set rmargin at screen 0.88 
# BUILD FROM BOTTOM TO TOP # 
TOP=0.92 # 
DY = 0.27 # DIMENSION OF Y 

set multiplot 
set grid 
set offset 0, 0, graph 0.05, graph 0.05 

#unset colorbox 
# BOTTOM GRAPH # 
set xlabel "Second of the Week [s]" 
set ylabel "Up [m]" offset 1.5 
set ytics -0.7, 0.2, 0.4 
set yrange[-0.75:0.35] 
set tmargin at screen TOP-2*DY 
set bmargin at screen TOP-3*DY 
plot file u 1:12:3 notitle palette 
# MIDDLE GRAPH # 
set xtics format '' 
unset xlabel 
set ytics -0.3, 0.2, 0.8 
set yrange[-0.35:0.75] 
set ylabel "North [m]" 
set tmargin at screen TOP-DY 
set bmargin at screen TOP-2*DY 
plot file u 1:11:3 notitle palette 
# TOP GRAPH # 
set title "test" 
set ylabel "East [m]" 
set ytics -0.7, 0.2, 0.4 
set yrange[-0.9:0.25] 
set tmargin at screen TOP 
set bmargin at screen TOP-DY 
plot file u 1:10:3 notitle palette 

unset multiplot 

der obige Code erzeugt den folgenden Inhalt:

In den Stellplätzen werden die Daten entsprechend dem Abstand von einem Ursprung dargestellt. Die Entfernung ist farbcodiert und die verwendete Palette ist rechts von jedem Diagramm aufgetragen.

Meine Frage wäre: - Wie bekomme ich die gleiche Grafik, aber mit einer einzigen vertikalen Palette auf der rechten Seite der 3 Plots? Ich möchte, dass eine einzelne Palette vom Anfang des ersten Diagramms (Osten) bis zum Ende des dritten Diagramms (Oben) angezeigt wird. Dies würde es mir erlauben, die Palette ebenfalls zu vergrößern und würde zu einer saubereren Darstellung führen.

Jede Hilfe wird sehr geschätzt.

Answer 1

Für die erste Verwendung

set colorbox user origin screen 0, screen 0.05 size screen XX, screen YY 

Wo Sie benötigen XX und YY, um die gewünschte colorbox Breite und heigh der drei Grundstücke zu passen.

dann für die zweiten zwei Parzellen, stellen nur

unset colorbox