Kopieren einer Datei in einen Ordner zu einem Zeitpunkt, wo es 100 Dateien und 100 Ordner

Question

mit Batch-Datei zu kopieren, ich habe zwei Ordner CopyFrom und CopyTo wo CopyFrom 100 Textdateien als 1.txt ... 100.txt genannt hat und in CopyTo Ordnern Ich habe 100 Ordner wie F1 ... F100. Nun mag ich eine Datei aus CopyFrom Ordnern in einen Ordner in CopyTo kopieren, so dass F11.txt enthalten, F2 enthalten 2.txt, ..., wird F100100.txt Datei enthalten.

Ich weiß, alle Ordner zu kopieren Ich kann etwas wie For /d %%a in (C:\Users\me\Desktop\ShortCuts\*) do xcopy "C:\Users\me\Desktop\Time.xls" "%%a" verwenden, aber ich konnte keine Möglichkeit finden, verschiedene Dateien in andere Ordner zu kopieren.

kann ich alle Dateien (For %%a in (C:\Users\me\Desktop\ShortCuts\*) Echo "%%a") im CopyFrom Ordner Echo und auch alle Ordner in CopyTo Ordner Echo kann aber konnte nicht herausfinden, mit beiden zu arbeiten zu bekommen, was ich suche.

Answer 1

den Quellort Gesetzt enthält die Dateien 1.txt-100.txt nur und das Zielverzeichnis enthält bereits alle F1-F100 Verzeichnisse, könnte der folgende Code-Schnipsel für Sie arbeiten:

@echo off 
setlocal EnableExtensions DisableDelayedExpansion 

rem // Define constants here: 
set "Pattern=*.txt" 
set "CopyFrom=." 
set "CopyTo=D:\Target" 

for %%F in ("%CopyFrom%\%Pattern%") do (
    ECHO copy "%%~F" "%CopyTo%\F%%~nF\" 
) 

endlocal 
exit /B 

Es Ist keine Aufzählung des Zielortes erfolgt, wird das Kopierziel einfach vom Quelldateinamen abgeleitet.

Nachdem Sie das Skript getestet haben, entfernen Sie den Großbuchstaben Befehl, um tatsächlich Dateien zu kopieren!

Answer 2

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    rem Configure paths 
    set "copyFrom=c:\somewhere" 
    set "copyTo=c:\anotherPlace" 

    rem Generate two lists, one with files and one with folders 
    dir /b /a-d "%copyFrom%\*" > "%temp%\copyFromFiles.txt" 
    dir /b /ad "%copyTo%\*" > "%temp%\copyToFolders.txt" 

    rem Assign each list as input to two streams and start processing  
    9< "%temp%\copyFromFiles.txt" 8< "%temp%\copyToFolders.txt" (
     call :matchFromWithTo 
    ) 

    rem Remove generated lists 
    del "%temp%\copyFromFiles.txt" 
    del "%temp%\copyToFolders.txt" 

    rem End 
    goto :eof 

:matchFromWithTo 
    rem Read file from stream 9 and leave if nothing read 
    <&9 set /p "file=" || goto :eof 
    rem Read folder from stream 8 and leave if nothing read 
    <&8 set /p "folder=" || goto :eof 

    rem Do the copy (debug: we will only echo the command) 
    echo copy "%copyFrom%\%file%" "%copyTo%\%folder%" 

    rem Keep reading until all files or folders are processed 
    goto :matchFromWithTo