Wie kann ich CSS-Definitionen in Dateien mit Perl in Inline-Stilattribute zusammenführen?

Question

Viele E-Mail-Clients mögen keine verknüpften CSS-Stylesheets oder sogar das eingebettete <style>-Tag, sondern möchten, dass das CSS inline als Stilattribute für alle Ihre Markups angezeigt wird.

• BAD: <link rel=stylesheet type="text/css" href="/style.css">
• BAD: <style type="text/css">...</style>
• WERKT: <h1 style="margin: 0">...</h1>

jedoch dieser Inline-Stil-Attribut Ansatz ist ein richtigen Schmerzen zu verwalten.

Ich habe Tools für Ruby und PHP gefunden, die eine CSS-Datei und ein separates Markup als Eingabe nehmen und Ihnen das zusammengefügte Ergebnis zurückgeben - eine einzelne Markupdatei mit allen CSS-Attributen, die in Stilattribute umgewandelt wurden.

Ich bin auf der Suche nach einer Perl-Lösung für dieses Problem, aber ich habe keine gefunden auf CPAN oder Google suchen. Irgendwelche Zeiger? Oder gibt es CPAN-Module, die man kombinieren könnte, um dasselbe Ergebnis zu erzielen?

• Rubin http://code.dunae.ca/premailer.web/
• PHP http://www.pelagodesign.com/sidecar/emogrifier/
• Perl?

Answer 1

Ich kenne keine vollständige, vorkonfektionierte Lösung.

CSS::DOM ‚s compute_style unterliegt so ziemlich die gleichen Einschränkungen wie emogrifier oben. Dieses Modul sollte in Verbindung mit HTML::TokeParser verwendbar sein, um etwas zu kochen.

Update: Hier ist ein Buggy Mischmasch der Dinge:

#!/usr/bin/perl 

use strict; 
use warnings; 

use CSS::DOM; 
use File::Slurp; 
use HTML::DOM; 
use HTML::TokeParser; 

die "convert html_file css_file" unless @ARGV == 2; 
my ($html_file, $css_file) = @ARGV; 

my $html_parser = HTML::TokeParser->new($html_file) 
    or die "Cannot open '$html_file': $!"; 

my $sheet = CSS::DOM::parse(scalar read_file $css_file); 

while (my $token = $html_parser->get_token) { 
    my $type = $token->[0]; 
    my $text = $type eq 'T' ? $token->[1] : $token->[-1]; 
    if ($type eq 'S') { 
     unless (skip($token->[1])) { 
      $text = insert_computed_style($sheet, $token); 
     } 
    } 
    print $text; 
} 

sub insert_computed_style { 
    my ($sheet, $token) = @_; 
    my ($tag, $attr, $attrseq) = @$token[1 .. 3]; 
    my $doc = HTML::DOM->new; 

    my $element = $doc->createElement($tag); 

    for my $attr_name (@$attrseq) { 
     $element->setAttribute($attr_name, $attr->{$attr_name}); 
    } 

    my $style = CSS::DOM::compute_style(
     element => $element, user_sheet => $sheet 
    ); 

    my @attrseq = (style => grep { lc $_ ne 'style' } @$attrseq); 
    $attr->{style} = $style->cssText; 

    my $text .= join(" ", 
     "<$tag", 
     map{ qq/$_='$attr->{$_}'/ } @attrseq); 
    $text .= '>'; 

    return $text; 
} 

sub skip { 
    my ($tag) = @_; 
    $tag = lc $tag; 
    return 1 if $tag =~ /^(?:h(?:ead|tml)|link|meta|script|title)$/; 
} 

Answer 2

können Sie verwenden CSS::Inlinerhttp://search.cpan.org/dist/CSS-Inliner/