Wie bekomme ich das GIT in Delphi 7?

Question

Ich versuche, das Global Interface Table mit dem folgenden Code (Delphi) zu erhalten:

uses Comobj, ActiveX; 

var 
    cGIT : IGlobalInterfaceTable = NIL; 
const 
    CLSID_StdGlobalInterfaceTable: TGUID = '{00000146-0000-0000-C000-000000000046}'; 


function GIT : IGlobalInterfaceTable; 
begin 
    if (cGIT = NIL) then 
     OleCheck (CoCreateInstance (CLSID_StdGlobalInterfaceTable, NIL, 
            CLSCTX_ALL, IGlobalInterfaceTable, cGIT)); 
    Result := cGIT; 
end; 

jedoch CoCreateInstance eine "Klasse nicht registriert" Ausnahme auslöst. Und tatsächlich: In HKCR/CLSID gibt es keinen Eintrag für {00000146- etc.}.

Welche DLL oder OCX sollte registriert werden, um diese Definition in der Registrierung zu erhalten? Oder mache ich es total falsch?

Answer 1

Hier ist meine Einheit, die es tut. Ich habe das zusammengefügt, als ich in D2006 kompiliert habe, aber ich sehe nicht, warum es in D7 anders wäre. Ich verwende es zum Speichern einer Schnittstelle zu einem DCOM-Server und teilen Sie es zwischen mehreren Threads.

unit GlobalInterfaceTable; 

interface 

uses Types, 
    ActiveX; 

type 
    IGlobalInterfaceTable = interface(IUnknown) 
    ['{00000146-0000-0000-C000-000000000046}'] 
    function RegisterInterfaceInGlobal (pUnk : IUnknown; const riid: TIID; out dwCookie : DWORD): HResult; stdcall; 
    function RevokeInterfaceFromGlobal (dwCookie: DWORD): HResult; stdcall; 
    function GetInterfaceFromGlobal (dwCookie: DWORD; const riid: TIID; out ppv): HResult; stdcall; 
    end; 

    function GIT: IGlobalInterfaceTable; 

implementation 

uses ComObj; 

const 
    CLSID_StdGlobalInterfaceTable : TGUID = '{00000323-0000-0000-C000-000000000046}'; 

function GIT: IGlobalInterfaceTable; 
begin 
    // This function call always returns the singleton instance of the GIT 
    OleCheck(CoCreateInstance (CLSID_StdGlobalInterfaceTable, NIL, CLSCTX_ALL, IGlobalInterfaceTable, Result)); 
end; 

end. 

Answer 2

Sie haben CLSID_StdGlobalInterfaceTable falsch definiert: Sie haben die GUID der Schnittstelle anstelle einer konkreten Klasse angegeben.

Ich habe nicht die Windows-Header-Dateien um, so kann ich gegen sie nicht überprüfen, aber eine Suche schlägt es sein sollte:

CLSID_StdGlobalInterfaceTable: TGUID = '{00000323-0000-0000-C000-000000000046}'; 

Answer 3

Haben Sie OleView32 verwendet, um die GUID der Klasse zu überprüfen ? Dieses Dienstprogramm ist im Windows SDK verfügbar und ermöglicht es Ihnen, die Registrierung von Schnittstellen viel einfacher als regedit zu gehen. Ich würde das Dienstprogramm als ein Muss für jede COM-Entwicklung einstufen.