Wie bekomme ich eine Ausgabe von einem Exec-Programm in Inno-Setup?

Question

Ist es möglich, eine Ausgabe einer Exec 'ed ausführbaren Datei zu erhalten?

Ich möchte dem Benutzer eine Infoabfrageseite zeigen, aber den Standardwert der MAC-Adresse im Eingabefeld anzeigen. Gibt es einen anderen Weg, dies zu erreichen?

Answer 1

Ja, verwenden Sie die Umleitung der Standardausgabe in eine Datei:

[Code] 

function NextButtonClick(CurPage: Integer): Boolean; 
var 
    TmpFileName, ExecStdout: string; 
    ResultCode: integer; 
begin 
    if CurPage = wpWelcome then begin 
    TmpFileName := ExpandConstant('{tmp}') + '\ipconfig_results.txt'; 
    Exec('cmd.exe', '/C ipconfig /ALL > "' + TmpFileName + '"', '', SW_HIDE, 
     ewWaitUntilTerminated, ResultCode); 
    if LoadStringFromFile(TmpFileName, ExecStdout) then begin 
     MsgBox(ExecStdout, mbInformation, MB_OK); 
     { do something with contents of file... } 
    end; 
    DeleteFile(TmpFileName); 
    end; 
    Result := True; 
end; 

Beachten Sie, dass es mehr als ein Netzwerkadapter sein, und folglich mehr MAC-Adressen zur Auswahl.

Answer 2

Ich musste das gleiche tun (Ausführen von Befehlszeilenaufrufen und das Ergebnis erhalten) und kam mit einer allgemeineren Lösung.

Es behebt auch seltsame Fehler, wenn zitierte Pfade in den tatsächlichen Aufrufen verwendet werden, indem das Flag /S für cmd.exe verwendet wird.

{ Exec with output stored in result. } 
{ ResultString will only be altered if True is returned. } 
function ExecWithResult(const Filename, Params, WorkingDir: String; const ShowCmd: Integer; 
    const Wait: TExecWait; var ResultCode: Integer; var ResultString: String): Boolean; 
var 
    TempFilename: String; 
    Command: String; 
begin 
    TempFilename := ExpandConstant('{tmp}\~execwithresult.txt'); 
    { Exec via cmd and redirect output to file. Must use special string-behavior to work. } 
    Command := 
    Format('"%s" /S /C ""%s" %s > "%s""', [ 
     ExpandConstant('{cmd}'), Filename, Params, TempFilename]); 
    Result := Exec(ExpandConstant('{cmd}'), Command, WorkingDir, ShowCmd, Wait, ResultCode); 
    if not Result then 
    Exit; 
    LoadStringFromFile(TempFilename, ResultString); { Cannot fail } 
    DeleteFile(TempFilename); 
    { Remove new-line at the end } 
    if (Length(ResultString) >= 2) and (ResultString[Length(ResultString) - 1] = #13) and 
    (ResultString[Length(ResultString)] = #10) then 
    Delete(ResultString, Length(ResultString) - 1, 2); 
end; 

Verbrauch:

Success := 
    ExecWithResult('ipconfig', '/all', '', SW_HIDE, ewWaitUntilTerminated, 
    ResultCode, ExecStdout) or 
    (ResultCode <> 0); 

Das Ergebnis auch in ein TStringList Objekt geladen werden kann, um alle Linien zu erhalten:

Lines := TStringList.Create; 
Lines.Text := ExecStdout; 
{ ... some code ... } 
Lines.Free;