Auswählen der Position der Variable (als Zelle) in Excel VBA

Question

So habe ich ein Problem bei der Auswahl der genauen Zelle eines formulierten Werts. Ich bin wirklich neu in VBA und ich suchte im Internet für mindestens 2 Tage nach einer wertvollen Antwort. Lassen Sie mich Ihnen den Code zeigen, der versucht zu erklären und zu erklären, was er danach tut;

Dim r As Range 
    MinTime = WorksheetFunction.Min(Range("C5:L14")) 
Set r = ActiveSheet.Cells.Find(MinTime) 
r.Select 
MinRow = ActiveCell.Row 
MinCol = ActiveCell.Column 

Also, was im versuchend zu tun ist, um die minimale Anzahl in einem Bereich mit worksheetfunction.min zu finden und der Zelle auszuwählen, die i ‚gerade gefunden haben. Richten Sie dann die Zeilen- und Spalteninformationen auf andere 2 Variablen. Aber dieser Code funktioniert nicht immer. Manchmal funktioniert es gut, manchmal nicht und ich bin im Moment ratlos. Jede Art von Hilfe wäre willkommen. Danke schon.

Answer 1

Ich vermute, dass Ihr Bereich tatsächlich Zeiten enthält. Der folgende Code findet den frühesten Zeitpunkt (den niedrigsten Wert im Bereich).

Private Sub MinTime() 

    Dim Rng As Range 
    Dim Mini As Range 
    Dim MiniValue As Double 
    Dim MinRow As Long, MinClm As Long 

    Set Rng = ActiveSheet.Range("C5:L14") 

    MiniValue = Application.Min(Rng) 
    With Rng 
     Set Mini = .Find(What:=MiniValue, _ 
         After:=.Cells(1), _ 
         LookIn:=xlFormulas, _ 
         LookAt:=xlWhole, _ 
         SearchOrder:=xlByRows, _ 
         SearchDirection:=xlNext, _ 
         MatchCase:=False, _ 
         MatchByte:=False) 
    End With 

    With Mini 
     MinRow = .Row 
     MinClm = .Column 
    End With 
End Sub 

Der Trick ist, LookIn:=xlFormulas anstelle des Standard-xlValues. Sie können 12:00 eingeben, aber die Formel der Zelle ist 0,5. Vorausgesetzt, dass das Minimum in dem Bereich ist, wenn Sie nach 0,5 in den Werten suchen, werden Sie es nicht finden, weil der "Wert" der Zelle in diesem Kontext (Verwirrung durch Microsoft, nicht mein Tun) "12:00" ist. Daher müssten Sie den gefundenen Mindestwert wieder in eine Zeichenfolge wie "12:00" konvertieren oder in den Formeln nach der 0,5 suchen.

Answer 2

Sie können dies auch tun, ohne die WorksheetFunction- oder die Find-Funktion zu verwenden. Das Erstellen eines Arrays und das anschließende Durchschleifen ist eine ziemlich einfache Möglichkeit, das zu finden, wonach Sie suchen. Versuchen Sie diese

Sub findMin(ByVal minRange As Range) 
Dim searchArr() As Range 
ReDim searchArr(1 To minRange.Rows.Count * minRange.Columns.Count) As Range 
Dim minVal As Double 
Dim i As Integer, i2 As Integer, outputRow As Integer, outputColumn As Integer 
For i2 = 0 To minRange.Columns.Count 
    For i = 0 To minRange.Rows.Count 
     searchArr(i + 1) = Cells(minRange.Row + i, minRange.Column + i2).Value 
    Next i 
Next i2 

    minVal = searchArr(1).Value 
    For i = 1 To UBound(searchArr) 
     If searchArr(i).Value < minVal Then 
      minVal = searchArr(i).Value 
      outputRow = searchArr(i).Row 
      outputColumn = searchArr(i).Column 
     End If 
    Next i 
End Sub 

Answer 3

Im Code Ihrer Frage verwenden Sie die Find-Methode für alle Zellen des Arbeitsblatts. Wie die Antwort von @ Gary's Student zeigt, sollten Sie die Find-Methode im selben Bereich aufrufen, in dem Sie den Min-Wert gefunden haben.

Außerdem gibt es mehrere Parameter für die Find-Methode, die einen Unterschied machen, wie zum Beispiel nach ganzen Werten suchen oder nicht, nach Formeln suchen oder nicht, nach einem bestimmten Format suchen oder nicht. Sie können leicht Informationen über die Find-Methode im Internet finden.

Hier ist mein nehmen auf Ihrem Code:

Sub MyAssignment() 
    Dim searchRange As Range 
    Dim minCell As Range 
    Dim minTime As Double 
    Dim minRow As Long 
    Dim minCol As Long 

    Set searchRange = ActiveSheet.Range("C5:L14") 
    minTime = WorksheetFunction.Min(searchRange) 

    Set minCell = searchRange.Find(minTime, searchRange.Cells(1), XlFindLookIn.xlValues, XlLookAt.xlWhole, MatchCase:=False, SearchFormat:=False) 
    minCell.Select 

    minRow = minCell.Row 
    minCol = minCell.Column 
End Sub 

Die Parameter, die Sie verwenden, wenn die Find-Methode von VBA Aufruf auf dem Suchen-Dialog gespiegelt wird, wie aus Excel (Strg + F) gesehen. Umgekehrt wirkt sich das Ändern der Optionen im Dialogfeld "Suchen" von Excel auf den nächsten FBA-Aufruf von VBA aus, da die Parameter, die Sie der Find-Methode nicht zur Verfügung stellen, die zuletzt im Dialogfeld verwendeten Werte annehmen.

Lassen Sie uns wissen, wie es sich herausstellt.