Alphabetisch sortiert mit VBA ab Zeile 5

Question

Ich versuche herauszufinden, wie man eine Datenbank automatisch in VBA in Spalte A alphabetisch sortiert. Klingt einfach, aber ich habe Header in den ersten 4 Zeilen und will es sortieren Linie 5 nach unten. Ich habe Tage gesucht, um einen Code zu finden, der das tut. Die nächst ich gelungen ist mit diesem

Private Sub Worksheet_Change(ByVal Target As Range) 
    On Error Resume Next 
    If Not Intersect(Target, Range("A:A")) Is Nothing Then 
     Range("A1").Sort Key1:=Range("A2"), _ 
      Order1:=xlAscending, Header:=xlYes, _ 
      OrderCustom:=1, MatchCase:=False, _ 
      Orientation:=xlTopToBottom 
    End If 
End Sub 

Das Problem code- ist, wenn ich versuche, die Linie Range("A1").Sort Key1:=Range("A2"), _-Range("A5").Sort Key1:=Range("A6"), _ ändern, wenn ich es testen, es sortiert noch 2 rudert und nicht 5 rudern wie vorgesehen. Ich weiß, dass ich etwas vermisse, aber ich kann einfach nicht sehen, was ich vermisse!

Answer 1

Bitte missbrauchen Sie OERN nicht (On Error Resume Next). Es ist so, als würde man den Code zum Schweigen bringen :). Behandeln Sie den Fehler richtig.

Another interesting read

Ist das, was Sie wollen?

Private Sub Worksheet_Change(ByVal Target As Range) 
    Dim lRow As Long 

    On Error GoTo Whoa 

    '~> Find the last row in Col A 
    lRow = Range("A" & Rows.Count).End(xlUp).Row 

    '~~> Check if it is greater than row 4 
    If lRow > 4 Then 
     Application.EnableEvents = False 

     '~~> Check if the change happened in the relevant range 
     If Not Intersect(Target, Range("A5:A" & lRow)) Is Nothing Then 
      '~~> Sort only the relevant range 
      Range("A4:A" & lRow).Sort Key1:=Range("A4"), _ 
             Order1:=xlAscending, _ 
             Header:=xlYes, _ 
             OrderCustom:=1, _ 
             MatchCase:=False, _ 
             Orientation:=xlTopToBottom, _ 
             DataOption1:=xlSortNormal 
     End If 
    End If 

Letscontinue: 
    Application.EnableEvents = True 
    Exit Sub 
Whoa: 
    MsgBox Err.Description 
    Resume Letscontinue 
End Sub