Filtering Row basierend auf Kontrollkästchen

Question

Ich habe einige VBA-Code, den ich verwenden wollte, um eine Zeile anstelle einer Spalte zu filtern. Ich habe jedoch einige Probleme, die ich nicht zu lösen scheint, an dieser Stelle habe ich mich selbst verwirrt.

Sub FilterRow() 
    Dim b As Object, cs As Integer 
    Set b = ActiveSheet.CheckBoxes(Application.Caller) 
    With b.TopLeftCell 
     cs = .Row 
    End With 

    Dim rng As Range, cel As Range, totalRng As Range 
    If ActiveSheet.AutoFilterMode = True Then 
     ActiveSheet.AutoFilterMode = False 
    End If 

    For Each cel In totalRng 
     If cel.Row <> cs Then 
      cel.EntireColumn.Hidden = True 
     Else 
      cel.EntireColumn.Hidden = False 
     End If 
    Next cel 

End Sub 

Ziel ist die Codeprüfung Spalten zu haben C: DX dieser spezifischen Reihe für einen Wert, wenn ein Wert NICHT dann diese Spalte zu verstecken gefunden ist. Letztendlich werden alle leeren Zellen in dieser bestimmten Zeile entfernt.

Answer 1

vorausgesetzt So FilterRow wird das Makro, das Sie das Kontrollkästchen zugewiesen haben, wird Folgendes tun, was ich denke, Sie versuchen zu tun:

Sub FilterRow() 
    Dim b As Object, cs As Integer 
    Set b = ActiveSheet.CheckBoxes(Application.Caller) 

    With b.TopLeftCell 
     cs = .row 
    End With 

    Dim rng As Range, cel As Range, totalRng As Range 
    Set totalRng = Range("C" & cs & ":DX" & cs) 

    If b.Value = 1 Then 
     If ActiveSheet.AutoFilterMode = True Then 
     ActiveSheet.AutoFilterMode = False 
     End If 

     For Each cel In totalRng 
     If cel.Value = "" Then 
      cel.EntireColumn.Hidden = True 
     Else 
      cel.EntireColumn.Hidden = False 
     End If 
     Next cel 
    Else 
     ' Set up autofilter here 
     totalRng.EntireColumn.Hidden = False 
    End If 

End Sub 

Da dieses Makro ausgelöst wird, wenn das Kontrollkästchen entweder aktiviert oder deaktiviert, habe ich die Logik so geändert, dass sie alle Spalten anzeigt, wenn das Kontrollkästchen deaktiviert ist (dh, wenn das Kontrollkästchen deaktiviert ist).