Entfernen einer Funktion von der Bühne

Question

ich mit meinem Code ein großes Problem haben

Ich habe eine Funktion namens „delayCallFuntions“:

function delayCallFuntions(delay: int, func: Function) { 
    var timer: Timer = new Timer(delay, 1); 
    timer.addEventListener(TimerEvent.TIMER, func); 
    timer.start(); 
} 

Und ich habe diese Funktion wie unten Verbindung zwischen 2 Punkt zu machen in meinem Bildschirm:

delayCallFuntions(1, function (e: Event) {timer011(wireColor);}); 

Und Funktion "timer011" macht die Verbindungen:

function timer011(firstColor: int): void { 
wireColor = firstColor; 
//GRID is a class 
//Path A to B 
var PathAB: Grid; 
PathAB = new Grid(4, 5, 20, 17, canvas, wireColor); 
this.addChild(PathAB); 

}

Mein Problem ist: ich einige dieser Funktionen wie "timer012" haben "timer013", ... dass sie nacheinander ausführen müssen. Wenn ich aus dieser Szene gehe und wieder zurückkomme, funktionieren immer noch einige dieser Funktionen, während ich sie brauche, um von Anfang an zu beginnen und eins nach dem anderen zu gehen.

zum Beispiel: wenn ich zurückkomme, wird "timer011" gestartet, während auch "timer016" gleichzeitig beendet wird.

hoffe jemand kann mir helfen, da dieses Problem mich frustriert hat.

Answer 1

Derzeit erstellen Sie jedes Mal einen neuen Timer, wenn Sie eine Funktion hinzufügen. Dieser Timer bleibt aufgrund des Ereignis-Listeners im Speicher und da er in der Funktion gekapselt ist, gibt es keine einfache Möglichkeit, ihn erneut zu referenzieren, um ihn zu stoppen.

Was wäre ein besserer Ansatz, ist es, nur einen global referenzierten Timer zu erstellen, so dass Sie es bei Bedarf stoppen können.

Hier ist ein Weg, dies erreichen könnte:

//create an array that will hold all the functions you are planning on calling 
var delayedFuncs:Array = []; 

//this var will be used to store the current function that will be called next 
var currentFuncObj:Object = null; //set it to null so it clears the value when you return to this frame 

//create a single, global timer reference for everything 
//don't initialize it here though 
//if you revisit this frame, you don't want to create a whole new timer, but keep using the previous one 
var funcTimer:Timer; 

//if the timer has already been created (you've been to this frame before), stop it 
if (funcTimer) { 
    funcTimer.stop(); 
}else { 
//if you haven't been to this frame before, create the timer and add the listener 
    funcTimer = new Timer(1,1); 
    funcTimer.addEventListener(TimerEvent.TIMER, nextFunc, false, 0, true); 
} 

//this function adds items to your queue. I've added the ability to also include parameters 
function delayCallFunctions(delay:int, func:Function, ... funcParams):void { 
    //add an object to the array that stores the function, delay, and any parameters to pass to that function 
    delayedFuncs.push({delay: delay, func: func, params: funcParams}); 

    //if the timer hasn't started running yet, start it since we've added something 
    if(!funcTimer.running) nextFunc(); 
} 

//this function runs when the timer completes 
function nextFunc(e:Event = null):void { 

    //if we have an existing function to call, call it 
    if (currentFuncObj){ 
     //invoke the function with the parameters 
     currentFuncObj.func.apply(null, currentFuncObj.params); 
    } 

    //if there are still items in the array, grab the next one 
    if(delayedFuncs.length > 0){ 
     //array.shift grabs the first element in the array and removes it from the array 
     currentFuncObj = delayedFuncs.shift(); 

     //reset the timer 
     funcTimer.reset(); 
     //set the appropriate delay 
     funcTimer.delay = currentFuncObj.delay; 
     //start the timer again 
     funcTimer.start(); 
    } 
} 

So, jetzt Sie, indem Sie verwenden würde:

delayCallFunctions(3000, trace, "hello", "world", "I'll be traced 3 seconds from now"); 
delayCallFunctions(2000, trace, "I'll be called 2 seconds after the last one"); 

Oder mit Ihren spezifischen Code:

delayCallFuntions(1000, timer011, wireColor); 

Jetzt können Sie jederzeit den globalen Timer anhalten (sagen Sie, Sie drücken eine Taste, um Szenen zu wechseln).

funcTimer.stop();