Wie bekomme ich eine Liste aller Dateien mit einer bestimmten Erweiterung aus einem bestimmten Verzeichnis?

Question

Ich verwende diesen Code eine Liste aller Dateien in einem bestimmten Verzeichnis zu erhalten:

opendir DIR, $dir or die "cannot open dir $dir: $!"; 
my @files= readdir DIR; 
closedir DIR; 

Wie ich diesen Code ändern kann oder etwas anhängen, so dass es nur für Textdateien und lädt nur schaut das Array mit dem Präfix des Dateinamens?

Beispiel Verzeichnisinhalt:

. 
.. 
923847.txt 
98398523.txt 
198.txt 
deisi.jpg 
oisoifs.gif 
lksdjl.exe 

Beispiel Array Inhalt:

files[0]=923847 
files[1]=98398523 
files[2]=198 

Answer 1

my @files = glob "$dir/*.txt"; 
for (0..$#files){ 
    $files[$_] =~ s/\.txt$//; 
} 

Answer 2

es genug ist, eine Zeile zu ändern:

my @files= map{s/\.[^.]+$//;$_}grep {/\.txt$/} readdir DIR; 

Answer 3

Um nur die“zu erhalten. txt "-Dateien können Sie einen Dateitest verwenden ator (-f: reguläre Datei) und eine Regex.

my @files = grep { -f && /\.txt$/ } readdir $dir; 

Andernfalls können Sie für nur Textdateien suchen, Perl -T (ascii-Textdatei Test Operator) mit

my @files = grep { -T } readdir $dir; 

Answer 4

Wenn Sie die neuen Funktionen von Perl 5.10 verwenden können, das ist, wie Ich würde es schreiben.

use strict; 
use warnings; 
use 5.10.1; 
use autodie; # don't need to check the output of opendir now 

my $dir = "."; 

{ 
    opendir my($dirhandle), $dir; 
    for(readdir $dirhandle){ # sets $_ 
    when(-d $_){ next } # skip directories 
    when(/^[.]/){ next } # skip dot-files 

    when(/(.+)[.]txt$/){ say "text file: ", $1 } 
    default{ 
     say "other file: ", $_; 
    } 
    } 
    # $dirhandle is automatically closed here 
} 

Oder wenn Sie sehr große Verzeichnisse haben, könnten Sie eine while Schleife verwenden.

{ 
    opendir my($dirhandle), $dir; 
    while(my $elem = readdir $dirhandle){ 
    given($elem){ # sets $_ 
     when(-d $_){ next } # skip directories 
     when(/^[.]/){ next } # skip dot-files 

     when(/(.+)[.]txt$/){ say "text file: ", $1 } 
     default{ 
     say "other file: ", $_; 
     } 
    } 
    } 
} 

Answer 5

Nur diese verwenden:

my @files = map {-f && s{\.txt\z}{} ? $_ :()} readdir DIR; 

Answer 6

Dies ist die einfachste Art, wie ich (wie in für Menschen lesbaren) unter Verwendung der glob-Funktion gefunden haben:

# Store only TXT-files in the @files array using glob 
my @files = grep (-f ,<*.txt>); 
# Write them out 
foreach $file (@files) { 
    print "$file\n"; 
} 

zusätzlich die „-f "stellt sicher, dass nur tatsächliche Dateien (und nicht Verzeichnisse) im Array gespeichert werden.