Wie std :: string in NSString konvertieren?

Question

Hallo ich versuche, einen Standard std::string in einen NSString umzuwandeln, aber ich habe nicht viel Glück.

kann ich konvertieren erfolgreich von einem NSString zu einem std::string mit dem folgenden Code

NSString *realm = @"Hollywood"; 
std::string REALM = [realm cStringUsingEncoding:[NSString defaultCStringEncoding]]; 

Jedoch habe ich einen Kompilierung-Fehler, wenn ich versuche, die folgende

NSString *errorMessage = [NSString stringWithCString:REALM encoding:[NSString defaultCStringEncoding]]; 

Der Fehler, den ich bekommen ist

Cannot convert 'std::string' to 'const char*' in argument passing 

Fehle ich hier etwas?

Vielen Dank im Voraus.

Answer 1

Get c-string aus std :: string für die Umwandlung:

NSString *errorMessage = [NSString stringWithCString:REALM.c_str() 
            encoding:[NSString defaultCStringEncoding]]; 

Answer 2

Erstens, haben Sie Objective-C++ zu verwenden hierfür im Geringsten zu arbeiten; einfachste Weg, um sicherzustellen, ist es, alle *.mm

Bei weitem die meisten verwendbar (nicht weiterentwickelt) manuelle Art und Weise eine C++ zu bekommen std::string in eine NSString auf Ihre *.m Dateien umbenennen mit:

std::string param; // <-- input 
NSString* result = [NSString stringWithUTF8String:param.c_str()]; 
NSString* alternative = [[NSString alloc] initWithUTF8String:param.c_str()]; 

Dies funktioniert In den meisten Fällen - und wenn Sie keine spezielle Codierungserkennung und -konvertierung durchführen, wird UTF-8 Ihnen ein gutes Ergebnis liefern, wenn nicht-lateinische Zeichen "einfach funktionieren".

Wenn Sie eine größere App erstellen oder Sie nicht die einzige sind, die daran arbeitet, werden Sie wahrscheinlich etwas benötigen, das einfacher anzuwenden ist.

von cocoa-dev mailing list archives

@interface NSString (cppstring_additions) 
+(NSString*) stringWithwstring:(const std::wstring&)string; 
+(NSString*) stringWithstring:(const std::string&)string; 
-(std::wstring) getwstring; 
-(std::string) getstring; 
@end 

@implementation NSString (cppstring_additions) 

#if TARGET_RT_BIG_ENDIAN 
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32BE); 
#else 
const NSStringEncoding kEncoding_wchar_t = CFStringConvertEncodingToNSStringEncoding(kCFStringEncodingUTF32LE); 
#endif 

+(NSString*) stringWithwstring:(const std::wstring&)ws 
{ 
    char* data = (char*)ws.data(); 
    unsigned size = ws.size() * sizeof(wchar_t); 

    NSString* result = [[NSString alloc] initWithBytes:data length:size encoding:kEncoding_wchar_t]; 
    return result; 
} 
+(NSString*) stringWithstring:(const std::string&)s 
{ 
    NSString* result = [[NSString alloc] initWithUTF8String:s.c_str()]; 
    return result; 
} 

-(std::wstring) getwstring 
{ 
    NSData* asData = [self dataUsingEncoding:kEncoding_wchar_t]; 
    return std::wstring((wchar_t*)[asData bytes], [asData length]/sizeof(wchar_t)); 
} 
-(std::string) getstring 
{ 
    return [self UTF8String]; 
} 

@end 

eingerichtet, dass mit in-Place (und entsprechend #import ed) Sie können jetzt:

NSString* result = [NSString stringWithstring:param]; 
string convertedBack = [result getstring]; 

Und das gleiche gilt für std::wstring, die mehr als praktisch.

Answer 3

ich auch habe festgestellt, dass:

NSString *nsString = [NSString stringWithFormat:@"%s",standardString]; 

Arbeiten wie ein Weltmeister.

Answer 4

NSString* mystring = [NSString stringWithUTF8String:stdstring.c_str()]; 

Answer 5

Apple hat jetzt eine neue Möglichkeit, die Sie möchten, dass Sie diese Konvertierung durchführen. In XCode7 habe ich die Option Bearbeiten> Konvertieren> Nach Modern Objective C Syntax ... verwendet, um das herauszufinden. Es verwendet ein Kurzzeichen @.

std::string sCPPString = "Hello World!"; 
NSString *sAppleString = @(sCPPString.c_str()); 

Answer 6

Hier ist der Code-Schnipsel/Beispiel:

string str_simple = "HELLO WORLD"; 

//string to NSString 
NSString *stringinObjC = [NSString stringWithCString:str_simple.c_str() 
           encoding:[NSString defaultCStringEncoding]];    
NSLog(stringinObjC);