Prompt Monad in Purescript

Question

Ich arbeite durch die Definition Prompt und seine Bind Instanz beschrieben here und versuchte herauszufinden, wie dies in Purescript aussehen würde.

Ich verwende Purescript.Exists für den existentiellen Typ. Mein defintion ist dann:

data PromptAskF p r a 
    = PromptAskF (p a) (a -> Prompt p r) 

type PromptAsk p r = Exists (PromptAskF p r) 

data Prompt p r 
    = Ask (PromptAsk p r) 
    | Answer r 

instance bindPrompt :: Bind (Prompt p) where 
    bind (Answer x) k = k x 
    bind (Ask ask) k = ??? 

Ich stecke auf das Schreiben der Ask Fall in der Bind Instanz und insbesondere, ich bin sehr verwirrt über die Typen, wenn sie mit runExists arbeiten.

Wie soll ich diese Instanz schreiben?

Danke,

Michael

Answer 1

so etwas sollte es tun:

data PromptAskF p r a 
    = PromptAskF (p a) (a -> Prompt p r) 

type PromptAsk p r = Exists (PromptAskF p r) 

mapPA 
    :: forall p r r' 
    . (forall a. (a -> Prompt p r) -> (a -> Prompt p r')) 
    -> PromptAsk p r 
    -> PromptAsk p r' 
mapPA f = runExists \(PromptAskF req cont) -> mkExists $ PromptAskF req (f cont) 

data Prompt p r 
    = Ask (PromptAsk p r) 
    | Answer r 

instance functorPrompt :: Functor (Prompt p) where 
    map f (Answer r) = Answer (f r) 
    map f (Ask ask) = Ask $ mapPA (map (map f)) ask 

instance applyPrompt :: Apply (Prompt p) where 
    apply = ap 

instance applicativePrompt :: Applicative (Prompt p) where 
    pure = Answer 

instance bindPrompt :: Bind (Prompt p) where 
    bind (Answer x) k = k x 
    bind (Ask ask) k = Ask $ mapPA (\cont ans -> cont ans >>= k) ask 

instance monadPrompt :: Monad (Prompt p) 

Die mapPA Funktion ist eine Bequemlichkeit, die PromptAskF Fortsetzung für die Aktualisierung ohne runExists/mkExists wiederholt zu haben.