Bedingte Formatierung zum Erkennen und Anpassen der Tabellengröße [Excel]

Question

Ich habe mehrere Tabellen (etwa 200) erstellt, die aus einer Dropdown-Liste der Benutzereingaben generiert werden. Es funktioniert, aber es ist hässlich. Ich habe jedoch über bedingte Formatierung abhängig von der Größe der Tabelle angewendet.

Was ich will, ist so etwas wie dieses:

wie unten werden:

Zu wissen, dass ich habe auch einige Tabellen, die wie folgt aussehen:

Wäre es eine Möglichkeit, dies zu tun ?

Answer 1

Sie können durch Tabellen iterieren, indem Sie ListObjects im Arbeitsblatt (oder in der Arbeitsmappe) durchlaufen und die gewünschten Rahmenformate anwenden (die Formatierung erfolgt über den Auswahlfall in der ApplyStyle-Funktion). Erfordert, dass Sie Ihre Tabellen so einrichten, dass sie als Listenobjekte erkannt werden.

Mein Code:

Option Explicit 
Public Sub TEST() 

    Dim edgesArr() 
    edgesArr = Array(xlEdgeLeft, xlEdgeTop, xlEdgeBottom, xlEdgeRight, xlInsideVertical, xlInsideHorizontal) 

    With ActiveSheet 

     Dim tbl As ListObject 

     For Each tbl In .ListObjects 

      FormatTable edgesArr, tbl 

     Next tbl 

    End With 

End Sub 

Public Sub FormatTable(ByVal edgesArr As Variant, ByRef tbl As ListObject) 

    Dim currEdge As Long 

    With tbl.Range 

     For currEdge = LBound(edgesArr) To UBound(edgesArr) 

      ApplyStyle CStr(edgesArr(currEdge)), .Borders(edgesArr(currEdge)) 

     Next currEdge 

    End With 

End Sub 
Public Sub ApplyStyle(ByVal currEdgeText As String, ByVal border As Object) 

    With border 

     .LineStyle = xlContinuous 
     .ColorIndex = xlAutomatic 

     Select Case currEdgeText 

     Case xlInsideVertical, xlInsideHorizontal 

       .Weight = xlMedium 

     Case Else 

       .Weight = xlThick 

     End Select 

    End With 

End Sub 

Sie können den aktuellen Bereich in eine Tabelle mit Syntax konvertieren wie in example unter:

Dim src As Range 
Dim ws As Worksheet 
Set src = Range("B5").CurrentRegion 
Set ws = ActiveSheet 
ws.ListObjects.Add(SourceType:=xlSrcRange, Source:=src, _ 
xlListObjectHasHeaders:=xlYes, tablestyleName:="TableStyleMedium28").Name = "Sales_Table"