Wie mache ich eine dynamische WHERE mit COALESCE, die eine OR-Klausel hat

Question

Ich habe immer dynamische WHERE Anweisungen mit COALESCE() gemacht, um entweder den übergebenen Wert zurückgeben oder alle Datensätze zurückgeben.

Allerdings kann ich es nicht tun, wenn ich gegen zwei Spalten überprüfen muss, und wenn ein Parameter nicht übergeben wurde dann alle Datensätze zurückgeben. Hier ist Schnipsel meines Code:

DECLARE @MaxAge INT = NULL --- Example value: 5 

SELECT 
    * 
FROM 
    dbo.Vehicle 
WHERE 
DATEPART(YEAR, RegistrationDate) <= 
CASE 
    WHEN @MaxAge IS NOT NULL 
    THEN (DATEPART(YEAR,GETDATE()) - @MaxAge) 
    ELSE DATEPART(YEAR, RegistrationDate) 
END 
OR 
DATEPART(YEAR, ProductionDate) <= 
CASE 
    WHEN @MaxAge IS NOT NULL 
    THEN (DATEPART(YEAR,GETDATE()) - @MaxAge) 
    ELSE DATEPART(YEAR, ProductionDate) 
END 

Was ich versuche (in einfachem Englisch) zu tun ist:

Gib mir alle Zeilen in dem Fahrzeug Tisch, an dem dem Jahr Teil des RegistrationDate ist kleiner als der @MaxAge oder der YEAR-Teil des ProductionDate ist kleiner als der @MaxAge. Wenn @MaxAge NULL ist, dann gib mir die ganze Menge, egal wann es gemacht oder registriert wurde.

Manchmal ist der Wert in der Tabelle NULL, wenn ein Fahrzeug noch nicht registriert wurde. Manchmal kann die NULL sein, wenn der Verkäufer einfach nicht weiß, wann es gemacht wurde.

Was wäre der beste Weg, um dies anzugehen? Ich habe versucht, in SQL-Büchern und online zu suchen, aber kann wirklich nichts finden, um dieser Situation zu entsprechen.

Answer 1

du etwas vereinfachen kann zurückzukehren:

SELECT * 
FROM dbo.Vehicle 
WHERE @MaxAge IS NULL -- return everything if null 
OR  DATEDIFF(YEAR, RegistrationDate, GETDATE()) <= @MaxAge 
OR  DATEDIFF(YEAR, ProductionDate, GETDATE()) <= @MaxAge 

Beachten Sie, dass, wenn @MaxAge ist null, die beide der OR ... <= @MaxAge Anweisungen werden false zurückgeben. Sie werden immer noch mit allem von WHERE @MaxAge IS NULL enden.

Ich gehe hier davon aus, dass @MaxAge die älteste Registrierung darstellt, die Ihnen wichtig ist. Mit einem MaxAge von 5 würden Sie alle Ergebnisse an oder nach '01/01/2011' zurückgeben.

Edit:

Per Erike Kommentar beachten, dass DATEDIFF() etwas schrulliges Verhalten hat, die Sie vielleicht nicht erwarten.

Bedenken Sie, dass diese beiden Aussagen äquivalent sind:

SELECT DATEDIFF(YEAR, '01/01/2011', GETDATE()) -- = 5 
SELECT DATEDIFF(YEAR, '12/31/2011', GETDATE()) -- = 5 

Um dies zu umgehen, können Sie versuchen:

SELECT * 
FROM dbo.Vehicle 
WHERE @MaxAge IS NULL -- return everything if null 
OR  DATEADD(YEAR, -@MaxAge, GETDATE()) <= RegistrationDate 
OR  DATEADD(YEAR, -@MaxAge, GETDATE()) <= ProductionDate 

Diese zurück@MaxAge Jahre von heute gehen wird (einschließlich der aktuellen Zeit) und alles zurückgeben, was danach passiert ist. In diesem Fall würde alles, was vor 5 Jahren und 10 Sekunden passiert ist, weggelassen. Um dies zu beheben, können Sie verwenden:

DECLARE @TodayNoTime datetime = DATEADD(dd, DATEDIFF(dd, 0, getdate()), 0) -- 05/25/2016 00:00:00.000 

SELECT * 
FROM dbo.Vehicle 
WHERE @MaxAge IS NULL -- return everything if null 
OR  DATEADD(YEAR, -@MaxAge, @TodayNoTime) <= RegistrationDate -- note the negative sign 
OR  DATEADD(YEAR, -@MaxAge, @TodayNoTime) <= ProductionDate 

Dies wird alles zurück, die heute vor @MaxAge Jahren passiert ist bis zu, unabhängig von der Zeit.

Schließlich funktioniert die Verwendung von COALESCE() in diesem Fall nicht, da Sie nur die eine oder die andere Spalte vergleichen, je nachdem, welche zuerst nicht null ist. Also, wenn RegistrationDate außerhalb Ihrer Parameter fällt, aber ProductionDate fällt in, werden Sie diesen Datensatz verpassen. Als solche habe ich diese Aussage aus der Antwort entfernt.

Answer 2

in einem OR zum WHERE Klausel Hinzufügen schien die richtigen Werte

DECLARE @MaxAge INT = NULL 

SELECT * 
FROM Vehicle 
WHERE @MaxAge IS NULL OR 
    (DATEPART(YEAR, RegistrationDate) <= 
      CASE WHEN @MaxAge IS NOT NULL 
      THEN (DATEPART(YEAR,GETDATE()) - @MaxAge) 
      ELSE DATEPART(YEAR, RegistrationDate) END 
OR 
    DATEPART(YEAR, ProductionDate) <= 
       CASE WHEN @MaxAge IS NOT NULL 
        THEN (DATEPART(YEAR,GETDATE()) - @MaxAge) 
        ELSE DATEPART(YEAR, ProductionDate) END 
    )