Wie können Sie zwei benannte Bereiche als Diagrammdatenquelle festlegen?

Question

Ich habe zwei benannte Bereiche wie unten beschrieben:

Set JRange = sht.Range(sht.Cells(StartRow, 10), sht.Cells(LastRow, 10)) 
Set DRange = sht.Range(sht.Cells(StartRow, 4), sht.Cells(LastRow, 4)) 

ich beide als Quellen für meine angegebene Diagramm Makro verwenden möchten. Das ist was ich habe:

Set Chart = ActiveSheet.ChartObjects.Add(Left:=300, Width:=325.9842519685, Top:=10, Height:=277.5118110236) 

With Chart 
    .Chart.SetSourceData Source:=Range(DRange) And (JRange), PlotBy:=xlColumns 
    .Chart.ChartType = xlLine 
    .Chart.ChartStyle = 2 
    .Height = 277.5118110236 
    .Width = 325.9842519685 

Jede Hilfe wäre sehr willkommen!

Answer 1

Sie können eine neue Serie Set Values und XValues getrennt:

Sub Tester() 

    Dim JRange As Range, DRange As Range, chtObj, cht As Chart 
    Dim StartRow, LastRow, sht 

    StartRow = 3 'for testing 
    LastRow = 15 'for testing 
    Set sht = ActiveSheet 

    Set JRange = sht.Range(sht.Cells(StartRow, 10), sht.Cells(LastRow, 10)) 
    Set DRange = sht.Range(sht.Cells(StartRow, 4), sht.Cells(LastRow, 4)) 


    Set chtObj = ActiveSheet.ChartObjects.Add(Left:=300, _ 
       Width:=325.9842519685, Top:=10, Height:=277.5118110236) 

    With chtObj.Chart 
     .ChartType = xlLine 
     .ChartStyle = 2 
     With .SeriesCollection.NewSeries 
      .Values = JRange 
      .XValues = DRange 
     End With 
    End With 

End Sub