Anzeige TPanel als Modal

Question

Ich habe eine Hauptform, mit mehreren Panels, von denen einige ausgeblendet sind. Wenn der Benutzer mit dem Hauptformular interagiert, muss ich einige der ausgeblendeten Bereiche sichtbar machen und sie in einer modalen Weise anzeigen, so dass der Benutzer nicht mit den anderen Teilen des Hauptformulars interagieren kann, bis sie mit dem Modal Panel abschließen .

Gibt es eine Möglichkeit, ein vorhandenes Bedienfeld in einem Formular modal anzuzeigen?

Ich würde gerne nicht Zyklus durch die wichtigsten Formen Kontrollen und deaktivieren/verstecken alles außer für das eine Panel, das ist die gemeinsame Antwort Entwickler haben gegeben, wenn andere diese gleiche Frage gestellt haben.

Mein Ziel ist es, einfach ein vorhandenes Panel auf dem Hauptformular in einer modalen Weise anzuzeigen, ohne die anderen Steuerelemente auf dem Hauptformular zu manipulieren.

Answer 1

Da ein TForm hat .ShowModal(), können wir leicht eine temporäre Form schaffen, die TPanel in das Formular verschieben, das Formular als modale anzuzeigen, für den Benutzer warten, um die Form zu schließen, dann bewegen Sie den TPanel wieder in seinen ursprünglichen Eltern vor Zerstörung der TForm.

Wenn Sie ein Formular mit einem versteckten TPanel genannt pnl und einen Knopf auf diesem Panel namens btnCloseModalPanel erstellen, dann wird der folgende Code zeigt pnl als modal, bis der Benutzer auf die Schaltfläche klickt.

begin 
    DisplayModalPanel(pnl); 
    // do something with 'pnl.data...' 
end; 

procedure TForm1.DisplayModalPanel(Panel: TPanel); 
var 
    frm: TForm; 
    old_top, old_left: Integer; 
    old_parent: TWinControl; 
    old_visible: Boolean; 
begin 
    frm := TForm.Create(Panel.Parent); 
    try 
    frm.BorderStyle := bsNone; 
    frm.Position := poOwnerFormCenter; 
    frm.Tag := 12921; // test in close button click, so we don't close the wrong form 

    // Rememer properties we can change and then restore them 
    old_top := Panel.Top; 
    old_left := Panel.Left; 
    old_parent := Panel.Parent; 
    old_visible := Panel.Visible; 

    // Move the panel to the modal form 
    Panel.Parent := frm; 
    Panel.Top := 0; 
    Panel.Left := 0; 
    Panel.Visible := True; 

    // Display the modal form 
    frm.AutoSize := True; 
    frm.ShowModal; 

    // Restore everything 
    Panel.Visible := old_visible; 
    Panel.Parent := old_Parent; 
    Panel.Left := old_left; 
    Panel.Top := old_top; 
    finally 
    FreeAndNil(frm); 
    end; 
end; 

procedure TForm1.btnCloseModalPanelClick(Sender: TObject); 
var 
    frm: TForm; 
begin 
    if pnl.Parent is TForm then 
    begin 
    frm := pnl.Parent as TForm; 
    if frm.Tag = 12921 then // don't close the wrong form 
     frm.Close; 
    end; 
end;