ein Befehlsfeld zum Aktualisieren von Daten in einer Tabelle

Question

Guten Tag Jungs Ich erstellte ein Benutzerformular auf Excel mit einer Combobox und eine Befehlsschaltfläche, die Befehlsschaltfläche für die Aktualisierung der Daten auf der Tabellenkalkulation basierend auf dem Element auf der Combobox ausgewählt und ein Textfeld mit Daten, das Problem ist jedes Mal, wenn ich auf die Befehlsschaltfläche klicken, aktualisiert es nicht die Daten, stattdessen geht es in die nächste Spalte und füllen Sie es. und ich möchte die Daten auf dem ausgewählten Element

aktualisiert werden das ist, was ich versucht

Private Sub CommandButton6_Click() 
    Dim lrCD As Long 
    lrCD = Sheets("Sheet2").Range("A" & Rows.Count).End(xlUp).Row 
    Sheets("Sheet2").Cells(lrCD + 1, "A").Value = ComboBox1.Text 
    Sheets("Sheet2").Cells(lrCD + 1, "B").Value = TextBox5.Text 

Answer 1

erstellen Sie Ihre Form, wie unten:

Spalte A in Sheet2 enthält eindeutige Werte, die in Ihrem Combobox angezeigt.

Dieser Code befindet sich innerhalb des Formulars.
Das Ereignis UserForm_Initialize() wird beim Öffnen des Formulars ausgelöst und füllt die Combobox mit Werten.
Das Ereignis CommandButton6_Click durchsucht Spalte A und platziert den Text in Textfeld5 neben dem ausgewählten Wert.

Private Sub UserForm_Initialize() 
    Dim lrCD As Long 
    'Populate ComboBox with values from column A on Sheet2. 
    With ThisWorkbook.Worksheets("Sheet2") 
     lrCD = .Range("A" & Rows.Count).End(xlUp).Row 
     Me.ComboBox1.RowSource = "'Sheet2'!" & .Range(.Cells(1, 1), .Cells(lrCD, 1)).Address 
    End With 
End Sub 

Private Sub CommandButton6_Click() 
    Dim rCell As Range 
    With ThisWorkbook.Worksheets("Sheet2") 

     'Look for the selected value in column A. 
     Set rCell = .Columns(1).Find(_ 
      What:=Me.ComboBox1.Value, _ 
      After:=.Cells(1, 1), _ 
      LookIn:=xlValues, _ 
      LookAt:=xlWhole) 

     'If a value is found place the textbox value in the column next to it. 
     If Not rCell Is Nothing Then 
      rCell.Offset(, 1) = Me.TextBox5.Value 
     End If 
    End With 

End Sub