Erstellen eines Hyperlinks aus Zelleninhalten in Excel VBA

Question

Ich versuche, Hyperlinks basierend auf dem Zelleninhalt in einem vom Benutzer ausgewählten Bereich von Zellen zu erstellen. Ich bin so weit gekommen, aber wenn es ausgeführt wird, durchläuft es eine Schleife, erzeugt aber keine Hyperlinks.

Sub AcctHyperlink() 
    Dim WorkRng As Range 
    On Error Resume Next 
    Set WorkRng = Application.Selection 
    Set WorkRng = Application.InputBox("Range", "Select Range", WorkRng.Address, Type:=8) 

    For i = WorkRng.Rows.Count To 1 Step -1 
     If WorkRng.Cells(i, 1).Value <> "" Then 

      WorkRng.Cells(i, 1).Hyperlink.Add Anchor:=WorkRng.Cells(i, 1), _ 
      Adress:="https://example.com/" & WorkRng.Cells(i, 1).Value & "/search", _ 
      TextToDisplay:=WorkRng.Cells(i, 1).Value 

     End If 
    Next 
End Sub 

Answer 1

Edited Nichts mehr als zwei Fehler und fehlende CStr() Anrufe! Hyperlink sollte Hyperlinks sein und Adress sollte Address sein. Der Code, den Sie kompiliert haben, weil Range.ItemVariant, nicht Range zurückgibt, so kann Excel solche Fehler zur Kompilierungszeit nicht kennzeichnen. Folgende Arbeiten auf meiner Excel 2013-Installation:

Option Explicit '<--- always use this for more robust code 

Sub AcctHyperlink() 
    Dim WorkRng As Range 
    'On Error Resume Next '<--- Omit for error checking 
    Set WorkRng = Application.Selection 
    Set WorkRng = Application.InputBox("Range", "Select Range", WorkRng.Address, Type:=8) 

    Dim i as Long '<--- Need this because of Option Explicit 
    Dim addr as String '<--- ditto 
    For i = WorkRng.Rows.Count To 1 Step -1 
     If WorkRng.Cells(i, 1).Value <> "" Then 
      addr = "https://insight.metavante.org/opstopb1/OpstopServlet/Search?activityID=ViewProfileLnNote&activityType=note&activityTrgtID=undefined&activityAction=search&profileView=&accountNumber=" & CStr(WorkRng.Cells(i, 1).Value) & "&accountType=&subAccountNumber=&prcsGrpID=136&RelatedFIs=136&searchBy=account" 
       ' Note: need CStr() 
      '       V--- "Hyperlinks" 
      WorkRng.Cells(i, 1).Hyperlinks.Add Anchor:=WorkRng.Cells(i, 1), _ 
      Address:=addr, _ 
      TextToDisplay:=CStr(WorkRng.Cells(i, 1).Value) 
      '^--- "Address" two lines up 
      '    ^^^^---- Need CStr() 
     End If 
    Next 
End Sub 

Answer 2

müssen Sie ändern sein:

Adress von Address und Hyperlink von Hyperlinks