Bestimmte Zeichen aus einer Datei im Stapel abrufen?

Question

Also meine Frage kommt aus dem Wunsch, bestimmte Zahlen aus einer Textdatei mit Batch zu bekommen. Hier ist die Textdatei I

 Force user logoff how long after time expires?:  Never 
     Minimum password age (days):       0 
     Maximum password age (days):       40 
     Minimum password length:        7 
     Length of password history maintained:    None 
     Lockout threshold:         Never 
     Lockout duration (minutes):       30 
     Lockout observation window (minutes):     30 
     Computer role:          WORKSTATION 
     The command completed successfully. 

zu lesen versuchen Wie Sie sehen können es nur die Standardausgabe des net accounts Befehls im Batch ist. Was ich versuche zu tun, ist eine Computer-Passwort-Politik zu sichern, aber auch eine Sicherung zu machen, wenn sie es rückgängig machen wollen. Ich habe das Skript, um es zu sichern, aber das Rückgängigmachen ist der schwierige Teil. Dieser Ausgang stammt aus dem Backup, das ich erstellt habe. Ich versuche, das alte Mindestalter für das Kennwort, das maximale Kennwortalter und die Mindestlänge für das Kennwort aus dieser Datei zu ermitteln. Sie sind derzeit 0, 40 und 7.

Ich bin relativ neu zu Batch-Programmierung, so dass jede Hilfe geschätzt werden würde. Danke wieder

Answer 1

@ECHO OFF 
SETLOCAL 
SET "sourcedir=U:\sourcedir" 
SET "filename1=%sourcedir%\q45181780.txt" 
FOR %%a IN (minpassage maxpaxxage minpasslen) DO SET "%%a=" 
FOR /f "usebackqtokens=1*delims=:" %%a IN ("%filename1%") DO (
IF "%%a"=="Minimum password age (days)" SET /a minpassage=%%b 
IF "%%a"=="Maximum password age (days)" SET /a maxpassage=%%b 
IF "%%a"=="Minimum password length" SET /a minpasslen=%%b 
) 
ECHO Min pass age=%minpassage% 
ECHO Max pass age=%maxpassage% 
ECHO Min pass len=%minpasslen% 

:: adding in the "net account" command 
:: Note that this command is merely ECHOed for testing. 
:: If all seems in order, remove the "ECHO " from the following command 

ECHO net accounts /minpwlen:%minpasslen% 

GOTO :EOF 

Sie müssten die Einstellung von sourcedir an Ihre Umstände anpassen.

Ich habe eine Datei namens q45181780.txt verwendet, die Ihre Daten für meine Tests enthält.

Löschen der Variablen verwendet werden (nur für den Fall haben sie alreadt einen zugewiesenen Wert bekam)

Lesen Sie jede Zeile der Datei, tokenising auf : und weisen das erste Token zu %%a, um die zweite %%b. Wenn %%a mit der signifikanten Zeichenfolge übereinstimmt, verwenden Sie set /a, um die Variable festzulegen (da diese Datenelemente numerisch sind)

Bericht.

Answer 2

Hier ist, wie ich es tun würde, (sprachspezifisch):

@Echo Off 
For %%A In (min max len) Do Set "%%A=" 
For /F "Tokens=2 Delims=:" %%A In ('Find "imum"^<"accountinfo.txt"' 
) Do For %%B In (%%A) Do If Not Defined min (Set "min=%%B" 
) Else If Not Defined max (Set "max=%%B") Else Set "len=%%B" 
For %%A In (min max len) Do Set %%A 
Pause 

Bitte denken Sie daran accountinfo.txt auf den Namen Ihrer tatsächlichen Nettokonten Dateiausgabe zu ändern.

---

Sie sollten auch in der Lage sein, nur die Werte zu lesen, ohne zu in eine Textdatei ausgibt:

@Echo Off 
For %%A In (min max len) Do Set "%%A=" 
For /F "Tokens=2 Delims=:" %%A In ('Net Accounts^|Find "imum"' 
) Do For %%B In (%%A) Do If Not Defined min (Set "min=%%B" 
) Else If Not Defined max (Set "max=%%B") Else Set "len=%%B" 
For %%A In (min max len) Do Set %%A 
Pause 

Answer 3

Inspiriert von Compo des zweiten Partie dachte ich, warum nicht die Variablennamen aus dem Text erhalten:

> type PassMinMax.cmd 
@Echo off 
For /F "tokens=1,2delims=:" %%A in ('net accounts^|find "imum"' 
) Do For /f "tokens=1-3" %%C in ("%%A") Do @Set /A %%D_%%C_%%E=%%B 
Set Pass 

Beispielausgabe:

> PassMinMax.cmd 
password_Maximum_age=42 
password_Minimum_age=0 
password_Minimum_length=0 

Answer 4

Dies könnte erreicht werden, indem jede Zeile mit einem Regex in PowerShell analysiert wird.

$lines = Get-Content -Path ./parsepw.txt 

foreach ($line in $lines) { 
    if ($line -match '\s*Minimum password age \(days\):\s*([0-9]*)\w*') { $minpwage = [int]$Matches[1] } 
    elseif ($line -match '\s*Maximum password age \(days\):\s*([0-9]*)\w*') { $maxpwage = [int]$Matches[1] } 
    elseif ($line -match '\s*Minimum password length:\s*([0-9]*)\w*') { $minpwlen = [int]$Matches[1] } 
} 

$minpwage 
$maxpwage 
$minpwlen