Wie erstelle ich eine Verknüpfung über die Befehlszeile in Windows?

Question

Ich möchte, dass mein .bat-Skript (test.bat) eine Verknüpfung zu sich selbst erstellt, damit ich es in meinen Windows 8-Startordner kopieren kann.

Ich habe diese Codezeile geschrieben, um die Datei zu kopieren, aber ich habe noch keine Möglichkeit gefunden, die genannte Verknüpfung zu erstellen, da Sie sehen, dass es nur das Skript kopiert.

xcopy "C:\Users\Gabriel\Desktop\test.bat" "C:\Users\Gabriel\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup" 

Können Sie mir helfen?

Answer 1

Sie könnten einen PowerShell-Befehl verwenden. Halten Sie dies in Ihrem Batch-Skript, und es wird eine Verknüpfung zu %~f0 in %userprofile%\Start Menu\Programs\Startup erstellen:

powershell "$s=(New-Object -COM WScript.Shell).CreateShortcut('%userprofile%\Start Menu\Programs\Startup\%~n0.lnk');$s.TargetPath='%~f0';$s.Save()" 

---

Wenn Sie es vorziehen, nicht Powershell zu verwenden, Sie mklink verwenden könnte eine symbolische Verknüpfung zu machen. Syntax:

mklink saveShortcutAs targetOfShortcut 

Siehe mklink /? in einem Konsolenfenster für die vollständige Syntax und this web page für weitere Informationen.

in Batch-Skript zu tun:

mklink "%userprofile%\Start Menu\Programs\Startup\%~nx0" "%~f0" 

Die Verknüpfung erstellt ist keine traditionelle LNK-Datei, aber es soll die gleiche trotzdem arbeiten. Beachten Sie, dass dies nur funktioniert, wenn die .bat-Datei von demselben Laufwerk wie Ihr Startordner ausgeführt wird. Außerdem sind anscheinend Admin-Rechte erforderlich, um symbolische Links zu erstellen.

Answer 2

Kann nicht mit reinem batch.Check die shortcutJS.bat getan werden - es ist ein jscript/bat Hybrid- und sollte mit .bat Erweiterung verwendet werden:

call shortcutJS.bat -linkfile "%~n0.lnk" -target "%~f0" -linkarguments "some arguments" 

Mit -help können Sie die anderen Optionen prüfen (Sie Symbol festlegen, admin Berechtigungen und usw.)

Answer 3

Ich präsentiere ein kleines Hybridskript [BAT/VBS], um eine Desktopverknüpfung zu erstellen. Und Sie können es natürlich zu Ihrem Zweck ändern.

@echo off 
mode con cols=87 lines=5 & color 9B 
Title Shortcut Creator for your batch and applications files by Hackoo 2015 
Set MyFile=%~f0 
Set ShorcutName=HackooTest 
(
echo Call Shortcut("%MyFile%","%ShorcutName%"^) 
echo ^'**********************************************************************************************^) 
echo Sub Shortcut(ApplicationPath,Nom^) 
echo Dim objShell,DesktopPath,objShortCut,MyTab 
echo Set objShell = CreateObject("WScript.Shell"^) 
echo MyTab = Split(ApplicationPath,"\"^) 
echo If Nom = "" Then 
echo Nom = MyTab(UBound(MyTab^)^) 
echo End if 
echo DesktopPath = objShell.SpecialFolders("Desktop"^) 
echo Set objShortCut = objShell.CreateShortcut(DesktopPath ^& "\" ^& Nom ^& ".lnk"^) 
echo objShortCut.TargetPath = Dblquote(ApplicationPath^) 
echo ObjShortCut.IconLocation = "Winver.exe,0" 
echo objShortCut.Save 
echo End Sub 
echo ^'********************************************************************************************** 
echo ^'Fonction pour ajouter les doubles quotes dans une variable 
echo Function DblQuote(Str^) 
echo DblQuote = Chr(34^) ^& Str ^& Chr(34^) 
echo End Function 
echo ^'********************************************************************************************** 
) > Shortcutme.vbs 
Start /Wait Shortcutme.vbs 
Del Shortcutme.vbs 
::***************************************Main Batch******************************************* 
cls 
echo Done and your main batch goes here ! 
echo i am a test 
Pause > Nul 
::******************************************************************************************** 

Answer 4

Der beste Weg ist, diese Batch-Datei auszuführen. offene Notizblock und Typ: -

@echo off 
echo Set oWS = WScript.CreateObject("WScript.Shell") > CreateShortcut.vbs 
echo sLinkFile = "GIVETHEPATHOFLINK.lnk" >> CreateShortcut.vbs 
echo Set oLink = oWS.CreateShortcut(sLinkFile) >> CreateShortcut.vbs 
echo oLink.TargetPath = "GIVETHEPATHOFTARGETFILEYOUWANTTHESHORTCUT" >> CreateShortcut.vbs 
echo oLink.Save >> CreateShortcut.vbs 
cscript CreateShortcut.vbs 
del CreateShortcut.vbs 

Speichern unter Dateiname.bat (Vorsicht beim Speichern wählen alle Dateitypen) funktionierte gut in Win XP.

Answer 5

Rohit Sahus Antwort funktionierte am besten für mich in Windows 10. Die PowerShell-Lösung lief, aber keine Verknüpfung erschien. Die JScript-Lösung gab mir Syntaxfehler. Ich habe mklink nicht probiert, da ich mich nicht mit Berechtigungen anlegen wollte.

Ich wollte die Verknüpfung auf dem Desktop angezeigt werden. Aber ich musste auch das Symbol, die Beschreibung und das Arbeitsverzeichnis festlegen. Beachten Sie, dass MyApp48.bmp ein 48 x 48-Pixel-Bild ist. Hier ist meine mod von Rohit Lösung:

@echo off 
cd c:\MyApp 
echo Set oWS = WScript.CreateObject("WScript.Shell") > CreateShortcut.vbs 
echo sLinkFile = "%userprofile%\Desktop\MyApp.lnk" >> CreateShortcut.vbs 
echo Set oLink = oWS.CreateShortcut(sLinkFile) >> CreateShortcut.vbs 
echo oLink.TargetPath = "C:\MyApp\MyApp.bat" >> CreateShortcut.vbs 
echo oLink.WorkingDirectory = "C:\MyApp" >> CreateShortcut.vbs 
echo oLink.Description = "My Application" >> CreateShortcut.vbs 
echo oLink.IconLocation = "C:\MyApp\MyApp48.bmp" >> CreateShortcut.vbs 
echo oLink.Save >> CreateShortcut.vbs 
cscript CreateShortcut.vbs 
del CreateShortcut.vbs 

Answer 6

link.vbs

set fs = CreateObject("Scripting.FileSystemObject") 
set ws = WScript.CreateObject("WScript.Shell") 
set arg = Wscript.Arguments 

linkFile = arg(0) 

set link = ws.CreateShortcut(linkFile) 
    link.TargetPath = fs.BuildPath(ws.CurrentDirectory, arg(1)) 
    link.Save 

Befehl

C:\dir>link.vbs ..\shortcut.txt.lnk target.txt