Wie finde ich die „beste“ oder die günstigste Position für das gegebene Netzwerk Excel

Question

Ich habe das folgende Netzwerk in dem Bild unten:

Netzwerk

Wie Sie das sehen können Antwort ist berechnet und bekannt. Aber die Antwort war leicht zu berechnen, da es nur wenige Zahlen gibt. Lassen Sie mich erklären, wie das funktioniert. Es gibt drei Standorte A, B und C. Um von A nach A oder von B nach B oder von C nach C zu reisen, kostet es $ 0, wie in den angegebenen Preisen zu sehen ist. Ähnlich kostet es von A nach B und von B nach C 1000 Dollar, und A nach C kostet 200 Dollar. Dann sind die festen Preise A = 20 $, B = C = 100 $. Und der 999999 stellt nur dar, dass der Pfad nicht genommen werden kann, was bedeutet, dass er nicht ausgewählt werden muss.

Wenn, wie in unserem Fall, nur EINE Position ausgewählt werden muss, dann werden alle Buchstaben und Buchstabenkombinationen mit diesem Buchstaben am Ende addiert, vorausgesetzt, dass es am billigsten ist, also die "beste" Lösung. Allerdings müssen alle diejenigen mit diesem Buchstaben am Ende ausgewählt werden. In unserem Beispiel haben wir also "C" als gewählten Ort, denn wenn Sie alle Buchstaben und ihre Kombinationen für "A" oder "B" hinzufügen, erhalten Sie nicht weniger als 1300 $. Eine andere Bedingung ist, dass es den Pfad vervollständigen muss.

Ich hoffe, dass Sinn machen. Ich möchte etwas in Excel, das $ 1300 finden kann, wenn ich viel mehr Zahlen eingeben muss.

Answer 1

Eine einfache SUMIFS() sollte die günstigste Route finden arbeiten:

=MIN(SUMIFS(4:4,3:3,"*" & {"B","C"}&"*",4:4,"<>999999")) 

Dann wird eine INDEX/MATCH den Ort zu finden:

=INDEX({"B","C"},MATCH(MIN(SUMIFS(4:4,3:3,"*" & {"B","C"} & "*",4:4,"<>999999")),SUMIFS(4:4,3:3,"*" & {"B","C"} & "*",4:4,"<>999999"),0)) 

---

EDIT

Um zu tun, was Sie mit Formeln wollen, würde eine andere Tabelle benötigen. Listen Sie alle möglichen Standorte in einer Spalte auf.

In einer zweiten Spalte verwendet diese Formel zu finden, wenn es nur ein Ausgangspunkt ist und kein Verkehr fließt oder durch sie:

=COUNTIFS($3:$3,"*" & A6,$4:$4,"<>999999")>2 

Jetzt können wir die Formeln von oben leicht ändern auf diese neue Tabelle zu entnehmen und die richtigen Antworten erhalten:

diese sind jetzt Matrixformeln:

Für den Wert der günstigsten Route:

=MIN(IF(B6:B8,SUMIFS(4:4,3:3,"*" & IF(B6:B8,A6:A8)&"*",4:4,"<>999999"),999999)) 

Für den Namen der günstigsten Lage:

=INDEX(A6:A8,MATCH(MIN(IF(B6:B8,SUMIFS(4:4,3:3,"*" & IF(B6:B8,A6:A8)&"*",4:4,"<>999999"),999999)),SUMIFS(4:4,3:3,"*" & A6:A8 &"*",4:4,"<>999999"),0)) 

Als Matrixformeln sie bestätigt werden müssen, mit Ctrl-Shift-Eingabe, wenn Bearbeiten Verlassen Modus statt Eingabe. Wenn es richtig gemacht wird, wird Excel {} um die Formel setzen.

---

Edit # 2

Hier sind die Formeln, die für die Helfer Spalten ohne die Notwendigkeit arbeiten:

=MIN(IF(COUNTIFS($3:$3,"*" &{"A","B","C"},$4:$4,"<>999999")>2,SUMIFS(4:4,3:3,"*" & IF(COUNTIFS($3:$3,"*" & {"A","B","C"},$4:$4,"<>999999")>2,{"A","B","C"})&"*",4:4,"<>999999"),999999)) 

und

=INDEX({"A","B","C"},MATCH(MIN(IF(COUNTIFS($3:$3,"*" &{"A","B","C"},$4:$4,"<>999999")>2,SUMIFS(4:4,3:3,"*" & IF(COUNTIFS($3:$3,"*" & {"A","B","C"},$4:$4,"<>999999")>2,{"A","B","C"})&"*",4:4,"<>999999"),999999)),SUMIFS(4:4,3:3,"*" & {"A","B","C"} & "*",4:4,"<>999999"),0)) 

Sie sind immer noch Matrix-Formeln und müssen mit Strg-Umschalt-Enter bestätigt werden.