JSON mit VBScript decodieren/codieren

Question

Ich habe ein schnelles Entwicklungstool für ein ERP-System, das nur VBScript erlaubt. Ich versuche eine einfache AJAX-Anfrage mit VBS zu erstellen. Das hat mit dem "Microsoft.XMLHTTP" -Objekt funktioniert.

Der nächste Schritt besteht darin, Daten von einem Webserver mit json zu empfangen. Aber in VBS scheint keine Funktion wie "json_decode" oder andere zu sein.

Kennt jemand eine Lösung? Oder ist die einzige Möglichkeit, meine eigene json-Funktion zu entwickeln?

Answer 1

Da JSON ein hierarchisches Datenformat ist, werden reguläre Ausdrücke und Split(), wie Peter vorgeschlagen hat, Sie nicht weit bringen.

Wenn Ihre Umgebung CreateObject() zulässt, können Sie möglicherweise ein fertiges COMponent in einer anderen Sprache verwenden (z. B. den Standard json2.js in eine .WSC- oder COM-.NET-DLL einbinden). Eine andere Option wäre die Verwendung einer anderen Sprache über Microsoft Script Control. Die Konsequenz dieses Ansatzes ist, dass Sie sich mit den Objekten/Arrays beschäftigen müssen, die von der anderen Sprache geliefert werden (einige Hinweise finden sich in dem von Peter referenzierten Thema).

Eine reine VBScript-Lösung kann here gefunden werden. Ich kann die Dokumentation nicht lesen, aber der Code kompiliert und funktioniert für einfache Testfälle - YMMV.

Answer 2

Sie sollten besser Ihre eigene basierend auf einer Abfrage hier auf JSON und ASP. Wie zB diese Any good libraries for parsing JSON in Classic ASP? Die meiste Zeit json2-Bibliothek verwendet wird, aber dies basiert auf Jscript so keine Option für Sie. Auch die meiste Zeit hat diese Art von JSON eine feste Struktur, so dass es nicht so schwierig sein sollte, mit einer Regularexpression zu parsen, wie ich in einigen Antworten gezeigt habe, wie die obige. Sie könnten einige Ihrer JSON veröffentlichen, so dass wir es mit einigen Routinen testen können.

Answer 3

Ich hatte ein ähnliches Problem, also schrieb ich eine JSONtoXML-Funktion in VBScript für eines meiner Projekte. Keine Garantien für dieses Skript (es ist vorgesehen, wie sie ist und hat Grenzen bekannt sind, wie nicht alle Arten von Escape-Sequenzen Handling):

Const stateRoot = 0 
Const stateNameQuoted = 1 
Const stateNameFinished = 2 
Const stateValue = 3 
Const stateValueQuoted = 4 
Const stateValueQuotedEscaped = 5 
Const stateValueUnquoted = 6 
Const stateValueUnquotedEscaped = 7 

Function JSONToXML(json) 
    Dim dom, xmlElem, i, ch, state, name, value 
    Set dom = CreateObject("Microsoft.XMLDOM") 
    state = stateRoot 
    For i = 1 to Len(json) 
    ch = Mid(json, i, 1) 
    Select Case state 
    Case stateRoot 
     Select Case ch 
     Case "[" 
     If dom.documentElement is Nothing Then 
      Set xmlElem = dom.CreateElement("ARRAY") 
      Set dom.documentElement = xmlElem 
     Else 
      Set xmlElem = XMLCreateChild(xmlElem, "ARRAY") 
     End If 
     Case "{" 
     If dom.documentElement is Nothing Then 
      Set xmlElem = dom.CreateElement("OBJECT") 
      Set dom.documentElement = xmlElem 
     Else 
      Set xmlElem = XMLCreateChild(xmlElem, "OBJECT") 
     End If 
     Case """" 
     state = stateNameQuoted 
     name = "" 
     Case "}" 
     Set xmlElem = xmlElem.parentNode 
     Case "]" 
     Set xmlElem = xmlElem.parentNode 
     End Select 
    Case stateNameQuoted 
     Select Case ch 
     Case """" 
     state = stateNameFinished 
     Case Else 
     name = name + ch 
     End Select 
    Case stateNameFinished 
     Select Case ch 
     Case ":" 
     value = "" 
     State = stateValue 
     End Select 
    Case stateValue 
     Select Case ch 
     Case """" 
     State = stateValueQuoted 
     Case "{" 
     Set xmlElem = XMLCreateChild(xmlElem, "OBJECT") 
     State = stateRoot 
     Case "[" 
     Set xmlElem = XMLCreateChild(xmlElem, "ARRAY") 
     State = stateRoot 
     Case " " 
     Case Chr(9) 
     Case vbCr 
     Case vbLF 
     Case Else 
     value = ch 
     State = stateValueUnquoted 
     End Select 
    Case stateValueQuoted 
     Select Case ch 
     Case """" 
     xmlElem.setAttribute name, value 
     state = stateRoot 
     Case "\" 
     state = stateValueQuotedEscaped 
     Case Else 
     value = value + ch 
     End Select 
    Case stateValueQuotedEscaped ' @@TODO: Handle escape sequences 
     value = value + ch 
     state = stateValueQuoted 
    Case stateValueUnquoted 
     Select Case ch 
     Case "}" 
     xmlElem.setAttribute name, value 
     Set xmlElem = xmlElem.parentNode 
     state = stateRoot 
     Case "]" 
     xmlElem.setAttribute name, value 
     Set xmlElem = xmlElem.parentNode 
     state = stateRoot 
     Case "," 
     xmlElem.setAttribute name, value 
     state = stateRoot 
     Case "\" 
     state = stateValueUnquotedEscaped 
     Case Else 
     value = value + ch 
     End Select 
    Case stateValueUnquotedEscaped ' @@TODO: Handle escape sequences 
     value = value + ch 
     state = stateValueUnquoted 
    End Select 
    Next 
    Set JSONToXML = dom 
End Function 

Function XMLCreateChild(xmlParent, tagName) 
    Dim xmlChild 
    If xmlParent is Nothing Then 
    Set XMLCreateChild = Nothing 
    Exit Function 
    End If 
    If xmlParent.ownerDocument is Nothing Then 
    Set XMLCreateChild = Nothing 
    Exit Function 
    End If 
    Set xmlChild = xmlParent.ownerDocument.createElement(tagName) 
    xmlParent.appendChild xmlChild 
    Set XMLCreateChild = xmlChild 
End Function 

Answer 4

Wie wäre es tut dies mit ASPJSON?
Verfügbar ab http://www.aspjson.com/

Ich bin über diese als Lösung für eine sehr alte Website zu verwenden, um einen Ajax-Aufruf (mit JQuery) mit den codierten Daten an eine MongoDB, für die Prüfung zu senden.

Answer 5

Check out https://github.com/rcdmk/aspJSON

nicht sicher, ob dies einen Bezug zu www.ASPJSON.com hat (inzwischen aufgelösten) in Logans Antwort erwähnt.