Laden Komponente mit benutzerdefinierten Eigenschaften (ohne setSource)

Question

Sagen wir, ich habe eine QML-Anwendung mit einer Symbolleiste:

ApplicationWindow { 
    header: Loader { 
    source: Qt.platform.os=="linux" ? "qrc:/linux/MyTools.qml" : "qrc:/MyTools.qml" 
    } 
} 

jedoch:

ApplicationWindow { 
    header: MyTools { 
    showAdminButtons: userIsAdmin() 
    } 
} 

ich dynamisch die Komponente unter Verwendung eines Loader zeigen auswählen können Wenn ich dieser Komponente benutzerdefinierte Eigenschaftswerte liefern möchte (wie oben showAdminButtons), muss ich die Methode setSource() verwenden:

ApplicationWindow { 
    header: Loader { 
    Component.onCompleted: { 
     var qml = Qt.platform.os=="linux" ? "qrc:/linux/MyTools.qml" : "qrc:/MyTools.qml"; 
     setSource(qml, {showAdminButtons:userIsAdmin()}); 
    } 
    } 
} 

Gibt es eine "QML-only" -Methode, um einem Loader Eigenschaften zu liefern, die Component.onCompleted nicht erfordert? (Ich kann nicht vollständig rechtfertigen, warum Component.onCompleted sich für mich wie eine grobe Hack-Problemumgehung anfühlt, aber es tut jedes Mal, wenn ich es verwenden muss. Es hat etwas mit der deklarativen Natur von QML gegenüber der prozeduralen Natur von JS zu tun.)

Answer 1

Methode 1: Bindung (oder eine einfache Zuordnung, wenn die Bindung nicht erforderlich ist), wenn Loader.onLoaded:

ApplicationWindow { 
    header: Loader { 
     source: Qt.platform.os=="linux" ? "qrc:/linux/MyTools.qml" : "qrc:/MyTools.qml" 
     onLoaded: { 
      item.showAdminButtons = Qt.binding(function() { return userIsAdmin(); } 
     } 
    } 
} 

Methode 2: verwenden Binding Typ:

ApplicationWindow { 
    header: Loader { 
     id: loader 
     source: Qt.platform.os=="linux" ? "qrc:/linux/MyTools.qml" : "qrc:/MyTools.qml" 
     Binding { 
      target: loader.item 
      property: "showAdminButtons" 
      value: userIsAdmin() 
     } 
    } 
}