Spinning 3D-Diagramm in PowerPoint-Präsentation

Question

Ich erstellte ein Makro in Excel, die ein 3D-Diagramm drehen wird. Ich habe das Diagramm in PowerPoint kopiert und den Code so eingerichtet, dass er in PowerPoint ausgeführt wird, wenn die Folie angezeigt wird. Der Code wird ausgeführt, aber ich kann nicht erreichen, dass er tatsächlich ändert, was auf dem Bildschirm angezeigt wird. Wenn sich die Folie im Bearbeitungsmodus befindet, rotiert der Graph. Irgendeine Idee, wie man den Code nicht nur zum Laufen bringt (ich kann sehen, dass die Debug-Nummern auftauchen), aber den Bildschirm im Präsentationsmodus aktualisieren? Mein Code ist:

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long) 

Public Sub SpinTheChart() 

    RotateX = ActivePresentation.Slides(2).Shapes(2).Chart.ChartArea.Format _ 
        .ThreeD.RotationX 

    Do While ActivePresentation.SlideShowWindow.View.CurrentShowPosition = 2 
     RotateX = RotateX + 7 
     If RotateX > 360 Then RotateX = RotateX - 360 
     ActivePresentation.Slides(2).Shapes(2).Chart.ChartArea.Format _ 
        .ThreeD.RotationX = RotateX 
     DoEvents 
     Sleep 125 
     Debug.Print RotateX 
    Loop 

End Sub 

Sub OnSlideShowPageChange() 
    Dim i As Integer 
    i = ActivePresentation.SlideShowWindow.View.CurrentShowPosition 
    If i = 2 Then SpinTheChart 
End Sub 

UPDATE: ich immer noch diese kämpfen werde. Es scheint einige recomendations sagen die aktuell angezeigte Grafik zu aktualisieren, die Sie verwenden müssen, unter den DoEvents:

SlideShowWindows(1).View.GotoSlide SlideSowWindows(1).View.CurrentShowPosition 

aber das funktioniert nicht. Es beendet jeden Code, der ausgeführt wird. Also wird die Do/Loop in der ersten Funktion verlassen und es geht nicht weiter zur zweiten Iteration.

Answer 1

Es scheint, dass Änderungen an Diagrammen die Aktualisierung von SlideShowView nicht auslösen. Aber Änderungen an Text in Formen werden dies tun. So ist der folgende Code dreht sich das Diagramm:

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long) 

Public Sub SpinTheChart() 

Set oSlide = ActivePresentation.Slides("Slide1") 
Set oChart = oSlide.Shapes("Diagramm 4").Chart 
oChart.ChartArea.Format.ThreeD.RotationX = 20 

snRotationX = oChart.ChartArea.Format.ThreeD.RotationX 

Do While ActivePresentation.SlideShowWindow.View.Slide.Name = "Slide1" 

    snRotationX = snRotationX + 7 
    If snRotationX > 360 Then snRotationX = snRotationX - 360 
    oChart.ChartArea.Format.ThreeD.RotationX = snRotationX 

    'oSlide.Shapes("Rechteck 7").TextFrame.TextRange.Text = snRotationX 
    oSlide.Shapes.Title.TextFrame.TextRange.Text = oSlide.Shapes.Title.TextFrame.TextRange.Text 

    DoEvents 
    Sleep 125 

Loop 
End Sub 

Sub OnSlideShowPageChange(ByVal SSW As SlideShowWindow) 
If SSW.View.Slide.Name = "Slide1" _ 
    Then SpinTheChart 
End Sub 

Sie sind vertraut mit den anderen Themen mit Makros während einer Powerpoint-Präsentation? Sie sind in solchen Umgebungen sehr empfindlich und ihre Auswirkungen müssen sorgfältig getestet werden.

Und OnSlideShowPageChange funktioniert nur, wenn die VBA zuvor aktiviert wurde. Der einfachste Weg ist das Öffnen und Schließen des VBA-Editors vor dem Start der Präsentation.

Grüße

Axel

Answer 2

Wenn das Diagramm im Bearbeitungsmodus dreht, warum Sie es als GIF- ein enthalten, dass in der Darstellung nicht aufnehmen?

ein animiertes GIF to Powerpoint Add: https://support.office.com/en-us/article/Add-an-animated-GIF-to-a-slide-3a04f755-25a9-42c4-8cc1-1da4148aef01

Aufnahme Ihres Bildschirms: http://www.screentogif.com