Looping durch mehrere benannte Bereiche und gehen ähnlich benannten Bereich VBA

Question

ich mehrere benannte Bereiche für einen boolean True/False Wert überprüfen möchten. Ich muss die 1-Zelle Validierungsbereiche überprüfen (in der Reihenfolge) und wenn das Ergebnis True ist, muss ich .Select den entsprechenden benannten Bereich (dh den benannten Bereich ohne das entsprechende "validation_" Präfix und das Unterprogramm zu verlassen. Der folgende Code funktioniert, aber es ist nicht DRY

Hier ist ein Ausschnitt den Kern der Frage zu erhalten, aber diese If-ElseIf weiterhin für viele andere benannte Bereiche:.

If Range("validation_name") = True Then 
    Range("name").Select 
    Exit Sub 
ElseIf Range("validation_category") = True Then 
    Range("category").Select 
    Exit Sub 
ElseIf Range("validation_subcategory") = True Then 
    Range("subcategory").Select 
    Exit Sub 
' ... and many more... 

Moeglichkeiten/Fragen:

• Ich glaube, ich entweder ein Array von benannten Bereichen und eine Reihe Bereiche resultierenden „go-to“ genannt nutzen könnte?
• Vielleicht könnte ich stattdessen eine collection verwenden?
• Nicht sicher, ob eine for Schleife oder eine while Schleife besser wäre?

Answer 1

einige „extra trocken“

Codes

Sub main() 
    Dim a As Variant 
    For Each a In Array("name", "category", "subcategory") 
     If Range("valid_" & a).Value = True Then 
      Range(a).Select 
      Exit Sub 
     End If 
    Next a 
End Sub 

Sub main2() 
    Dim r As Range, f As Range   
    Set r = Union(Range("validation_date"), Range("validation_name"), Range("validation_subcategory"), Range("validation_category")) 
    Set f = r.Find(what:="true", LookIn:=xlValues, lookat:=xlWhole, MatchCase:=False) 
    If Not f Is Nothing Then Range(Replace(f.name.name, "validation_", "")).Select 
End Sub 

Answer 2

Ich gehe davon aus, dass diese 1-Zellbereiche. Wenn ja, sollten folgende Arbeiten:

Sub SelectRange() 
    Dim i As long, A As Variant 
    A = Array("validation_name", "validation_category", "validation_subcategory") 
    For i = 0 To UBound(A) 
     If Range(A(i)).Value = True Then 
      Range(Split(A(i),"_")(1)).Select 
      Exit Sub 
     End If 
    Next i 
End Sub 

Answer 3

Sie können mit Schleife durch alle genannten Bereiche so etwas wie:

Dim xlName As Name 
For each xlName In ActiveWorkbook.Names 
    If xlName.Name Like "validation_*" And Range(xlName.Name) = True Then 
     Application.Goto Replace(xlName.Name, "validation_", ""), True 
     Exit Sub 
    End If 
Next 

oder geben Sie sie wie diese

For each strName In Split("name category subcategory") 
    If Range("validation_" & strName) = True Then 
     Application.Goto strName, True 
     Exit Sub 
    End If 
Next 

aktualisieren

Entschuldigung, ich habe die ganze Frage nicht gelesen. Scheint, als ob Sie irgendeine Art von Schlüssel verwenden - Wert Sammlung

pairs = Array(Array("validation_name", "name"), _ 
       Array("validation_category", "category"), _ 
       Array("validation_subcategory", "subcategory")) 

For each pair In pairs 
    If Range(pair(0)) = True Then 
     Application.Goto pair(1), True 
     Exit Sub 
    End If 
Next