Möglichkeit, mehrere Excel-Dateien nebeneinander zu verschmelzen

Question

Ist es möglich, die Excel-Dateien Seite an Seite zusammenzuführen. Angenommen habe ich zwei separate Excel-Dateien in Laufwerk C gespeichert, mit dem Namen A und B zum Beispiel Datei-A ist wie folgt:

BB \t LL \t KO \t PO 
 
A \t C \t D \t A 
 
A \t C \t D \t A 
 
A \t C \t D \t A 
 
A \t C \t D \t A

Datei B ist wie:

WW \t YY \t ZZ \t XX 
 
Q \t C \t D \t Z 
 
Q \t C \t D \t Z 
 
Q \t C \t D \t Z 
 
Q \t C \t D \t Z

Ich brauche dies:

BB \t LL \t KO \t PO \t WW \t YY \t ZZ \t XX 
 
A \t C \t D \t A \t Q \t C \t D \t Z 
 
A \t C \t D \t A \t Q \t C \t D \t Z 
 
A \t C \t D \t A \t Q \t C \t D \t Z 
 
A \t C \t D \t A \t Q \t C \t D \t Z

Dank

Answer 1

ging ich davon aus, dass die Tabellen in Zelle A1 (die linke obere Zelle der Tabelle) beginnen und dass Sie 4x4-Tabellen haben (man kann leicht dieses Verhalten verallgemeinert) . Sie müssen diesen Code in einem Arbeitsblatt ausführen, in dem die Daten zusammengeführt werden sollen. Sie müssen auch die Pfade zu den Dateien im Code angeben und sicherstellen, dass die Namen der Blätter korrekt sind.

Sub merge() 
Dim actWb, wb As Workbook 
Dim i, j As Integer 
'set workbooks, so you can switch between them during the program 
Set actWb = Application.ActiveWorkbook 
'here you also open workbook you want to copy data from 
Set wb = Workbooks.Open("PATH TO THE FILE") 
'loop through the range you want to copy 
For i = 1 To 4 
    For j = 1 To 4 
     actWb.Sheets("Sheets1").Cells(i, j).Value =  wb.Sheets("Sheets1").Cells(i, j).Value 
    Next j 
Next i 
'close the workbook 
wb.Close 
'repeat above for the other workbook 
Set wb = Workbooks.Open("PATH TO THE OTHER FILE") 

For i = 1 To 4 
    For j = 1 To 4 
     actWb.Sheets("Sheets1").Cells(i, j + 4).Value =  wb.Sheets("Sheets1").Cells(i, j).Value 
    Next j 
Next i 
wb.Close 

End Sub 

Hope it :)

Answer 2

hilft Ihnen, eine Function, die Pflege Werte eines bestimmten Arbeitsblatt von einer bestimmten Arbeitsmappe zu speichern Zellen nimmt verwenden könnten in einer Variant Variable, wie die folgende:

Function GetWBValues(fullFileName As String, shtName As String, values As Variant) As Boolean 
    On Error GoTo ExitFunction 
    With Workbooks.Open(fullFileName).Worksheets(shtName) '<--| try opening passed file and accessing its passed sheet name 
     values = .UsedRange.Value 
     .Parent.Close False '<--| close just opened workbook without saving any changes 
    End With 
    GetWBValues = True '<--| set function return value to 'True' to signal calling sub that values has been successfully read 
ExitFunction: 
End Function 

durch einige "main" Aufruf Code ausgenutzt werden, wie folgt:

Option Explicit 

Sub merge() 
    Dim values As Variant 

    If GetWBValues("C:\Desktop\......\File1.xlsx", "Sheet1", values) Then 
     Cells.Resize(UBound(values, 1), UBound(values, 2)).Value = values 
    End If 

    If GetWBValues("C:\Desktop\......\File2.xlsx", "Sheet4", values) Then 
     With ActiveSheet.UsedRange 
      .Columns(.Columns.Count + 1).Resize(UBound(values, 1), UBound(values, 2)).Value = values 
     End With 
    End If 
End Sub