Perl: Wie übergeben und verwenden Sie ein lexikalisches Datei-Handle zu einer Subroutine als benanntes Argument?

Question

Ich möchte eine lexikalische Datei-Handle zu einem Unterprogramm übergeben ein benanntes Argument, aber die folgenden nicht kompiliert:

#!/usr/bin/perl -w 
use strict; 

my $log_fh; 
my $logname = "my.log"; 

sub primitive { 
    my ($fh, $m) = @_; 
    print $fh $m; 
} 

sub sophisticated { 
    my ($args) = @_; 
    print $args->{m}; 
    print $args->{fh} $args->{m} ; 
} 

open $log_fh, ">", $logname; 

print $log_fh "Today I learned ...\n"; 

primitive($log_fh,"... the old way works ...\n"); 

sophisticated({ 
    fh=>$log_fh, 
    m=>"... and the new way requires an intervention by SO.", 
    }); 
close $log_fh; 

Die Beschwerde ist:

Scalar found where operator expected at ./lexical.file.handle.pl line 15, near 
} $args" 
(Missing operator before $args?) 

$ perl --version 

This is perl, v5.10.1 

Es funktioniert O. K. Wenn ich die primitive Technik der Übergabe von Argumenten verwende, funktioniert die Named-Argument-Hash-Technik für die Nachricht Teil, nur nicht für die Datei behandeln Teil. Benötige ich eine neue Version von Drucken?

Answer 1

Wenn Sie einen komplexen Ausdruck haben, die eine Dateihandle zurückgibt (wie $args->{fh}) Sie müssen die Syntax ein wenig eindeutig zu machen, indem sie einige zusätzliche curlies Zugabe:

print { $args->{fh} } $args->{m}; 

Dies ist aufgrund der seltsamen Art und Weise Der Operator print wurde entworfen, ohne Komma zwischen dem Dateihandle und der Liste der zu druckenden Objekte.

Alternativ könnten Sie das Dateihandle aus Ihrer Argumente hashref zuerst, z.

my $fh = $args->{fh}; 
print $fh $args->{m}; 

Answer 2

friedo's answer deckt Ihr Problem, aber es gibt eine stilistische Frage ich darauf hinweisen möchte. Sie müssen nicht alles in einen anonymen Hash einbinden, um benannte Argumente zu emulieren. Ein Hash-Initialisierer ist nur eine Liste, die als Schlüssel/Wert-Paare interpretiert wird. Vorbei an einer solchen Liste zu einem Sub bietet eine sauberere Syntax für den Anrufer:

sub sophisticated { 
    my %arg = @_; 
    print $arg{m}; 
    print {$arg{fh}} $arg{m}; 
} 

sophisticated(fh => $log_fh, m => "Hello, world!\n");