XSLT Apply Vorlagen nicht auf der gleichen Linie

Question

Ich habe eine ziemlich grundlegende Frage heute. Warum werden die Attribute aus allen Elementen nicht zusammengefügt?

Meine gewünschte Ausgabe ist "Last_Name", "First_Name", "DOB" (wenn Bene_DOB existiert dann nicht DOB_DEP verwenden)
So:
"Gibson", "Mel", "1965-01- 01"
"Norris", "Chuck"

Aber ich bin immer:

"Norris", "Gibson", "Chuck", "Mel",

1965-01-01 12345-01

1965-01-01
12345-01

Ich habe diese XML

<?xml version='1.0' encoding='UTF-8'?> 
<wd:Report_Data xmlns:wd="urn:com.workday.report/BCBSLA_CR_OFAC_BENE"> 
<wd:Report_Entry> 
<wd:BENE_ALL> 
    <wd:Last_Name>Norris</wd:Last_Name> 
    <wd:First_Name>Chuck</wd:First_Name> 
    <wd:REF_ID>12345-01</wd:REF_ID> 
</wd:BENE_ALL>  
    <wd:Last_Name>Gibson</wd:Last_Name> 
    <wd:First_Name>Mel</wd:First_Name> 
    <wd:REF_ID>12345-02</wd:REF_ID> 
</wd:BENE_ALL> 
<wd:BENE_PEOPLE> 
    <wd:BENE_DOB>1965-01-02</wd:BENE_DOB> 
    <wd:Ben_Ref_ID>12345-01</wd:Ben_Ref_ID> 
</wd:BENE_PEOPLE> 
<wd:BENE_PEOPLE> 
    <wd:BENE_DOB>1955-01-10</wd:BENE_DOB> 
    <wd:Ben_Ref_ID>12345-02</wd:Ben_Ref_ID> 
</wd:BENE_PEOPLE> 
<wd:DEP> 
    <wd:DOB_Dep>1965-01-01</wd:DOB_Dep> 
    <wd:Dep_Ref_ID>12345-01</wd:Dep_Ref_ID> 
</wd:DEP> 
</wd:Report_Entry> 

Hier ist mein XSLT:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:xsd="http://www.w3.org/2001/XMLSchema" 
       exclude-result-prefixes="xsl" 
       xmlns:wd="urn:com.workday.report/BCBSLA_CR_OFAC_BENE" 
       version="2.0"> 


    <xsl:output method="text"/> 


    <xsl:template match="/"> 
    <xsl:apply-templates/> 
    </xsl:template> 

    <xsl:template match="wd:BENE_ALL"> 
    <xsl:apply-templates select="wd:EMPLID" mode="csv"/> 
    <xsl:apply-templates select="wd:Last_Name" mode="csv"/> 
    <xsl:apply-templates select="wd:First_Name" mode="csv"/> 
    </xsl:template> 


    <xsl:template match="wd:BENE_People"> 
    <xsl:apply-templates select="wd:DOB_Bene" mode="csv" /> 
    </xsl:template> 


    <!--<xsl:choose> 
     <xsl:when test= 
    </xsl:choose>--> 


    <xsl:template match="*" mode="csv"> 
    <xsl:value-of select="concat('&quot;', ., '&quot;,')" /> 
    </xsl:template> 

    <xsl:template match="*" mode="csv-nl"> 
    <xsl:value-of select="concat('&quot;', ., '&quot;&#xA;')" /> 
    </xsl:template> 

</xsl:stylesheet> 

Danke für jede Hilfe!

Answer 1

Wenn ich die Struktur Ihres XML richtig verstanden habe, müssen Sie eine neue Datenzeile für jede Gruppe von Elementen erstellen, die mit Last_Name beginnt. In XSLT 2.0, indem Sie diese erreicht werden könnte:

<xsl:template match="/Report_Data"> 
    <xsl:for-each-group select="Report_Entry/BENE_ALL/*" group-starting-with="Last_Name"> 
     <xsl:value-of select="concat('&quot;', ., '&quot;,')" /> 
     <xsl:value-of select="concat('&quot;', current-group()[self::First_Name], '&quot;&#10;')" /> 
    </xsl:for-each-group> 
</xsl:template> 

Rückkehr:

"Norris","Chuck" 
"Gibson","Mel" 

---

den Bene_DOB Wert hinzuzufügen, könnten Sie eine key wie folgt verwenden:

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xpath-default-namespace="urn:com.workday.report/BCBSLA_CR_OFAC_BENE"> 
<xsl:output method="text" encoding="UTF-8"/> 

<xsl:key name="person-dob" match="BENE_DOB" use="following-sibling::Ben_Ref_ID[1]" /> 

<xsl:template match="/Report_Data"> 
    <xsl:for-each-group select="Report_Entry/BENE_ALL/*" group-starting-with="Last_Name"> 
     <xsl:value-of select="concat('&quot;', ., '&quot;,')" /> 
     <xsl:value-of select="concat('&quot;', current-group()[self::First_Name], '&quot;,')" /> 
     <xsl:value-of select="concat('&quot;', key('person-dob', current-group()[self::REF_ID]), '&quot;&#10;')" /> 
    </xsl:for-each-group> 
</xsl:template> 

</xsl:stylesheet> 

Demo: http://xsltransform.net/naZXpX2

Dies ist der Schlüssel angenommen werden paarweise von BENE_DOB, Ben_Ref_ID aufgeführt.

---

Wenn Sie möchten, können Sie Codewiederholung durch die Definition einer Funktion als reduzieren könnte:

<xsl:function name="my:quote"> 
    <xsl:param name="text"/> 
    <xsl:sequence select="concat('&quot;', $text, '&quot;')" /> 
</xsl:function> 

und dann:

<xsl:template match="/Report_Data"> 
    <xsl:for-each-group select="Report_Entry/BENE_ALL/*" group-starting-with="Last_Name"> 
     <xsl:value-of select="my:quote(.), my:quote(current-group()[self::First_Name]), my:quote(key('person-dob', current-group()[self::REF_ID]))" separator=","/> 
     <xsl:text>&#10;</xsl:text> 
    </xsl:for-each-group> 
</xsl:template> 

Demo: http://xsltransform.net/naZXpX2/1