HTML zu CALS-Tabellen?

Question

Ich überprüfe, ob jemand ein XSLT herumliegen hat, das HTML-Tabellen in CALS umwandelt. Ich habe eine Menge Material dafür gefunden, in die andere Richtung zu gehen (CALS in HTML), aber nicht aus HTML. Ich dachte, jemand hätte das schon mal gemacht, also muss ich das Rad nicht neu erfinden. Ich bin nicht auf der Suche nach einer vollständigen Lösung. Nur ein Ausgangspunkt.

Wenn ich weit genug allein komme, werde ich es für zukünftige Referenz veröffentlichen.

Answer 1

ich mit einer viel einfacheren Lösung zu kommen haben als das, was zu @Flack verbunden:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
<xsl:template match="tbody"> 
    <xsl:variable name="maxColumns"> 
     <xsl:for-each select="tr"> 
      <xsl:sort select="sum(td/@colspan) + count(td[not(@colspan)])" data-type="number"/> 
      <xsl:if test="position() = last()"> 
       <xsl:value-of select="sum(td/@colspan) + count(td[not(@colspan)])"/> 
      </xsl:if> 
     </xsl:for-each> 
    </xsl:variable> 
    <tgroup> 
     <xsl:attribute name="cols"> 
      <xsl:value-of select="$maxColumns"/> 
     </xsl:attribute> 
     <xsl:apply-templates select="@*|node()"/> 
    </tgroup> 
</xsl:template> 

<xsl:template match="td[@colspan > 1]"> 
    <entry> 
     <xsl:attribute name="namest"> 
      <xsl:value-of select="sum(preceding-sibling::td/@colspan) + count(preceding-sibling::td[not(@colspan)]) + 1"/> 
     </xsl:attribute> 
     <xsl:attribute name="nameend"> 
      <xsl:value-of select="sum(preceding-sibling::td/@colspan) + count(preceding-sibling::td[not(@colspan)]) + @colspan"/> 
     </xsl:attribute> 
     <xsl:apply-templates select="@*[name() != 'colspan']|node()"/> 
    </entry> 
</xsl:template> 

<xsl:template match="tr"> 
    <row> 
     <xsl:apply-templates select="@*|node()"/> 
    </row> 
</xsl:template> 

<xsl:template match="td"> 
    <entry> 
     <xsl:apply-templates select="@*|node()"/> 
    </entry> 
</xsl:template> 

<xsl:template match="td/@rowspan"> 
    <xsl:attribute name="morerows"> 
     <xsl:value-of select=". - 1"/> 
    </xsl:attribute> 
</xsl:template> 

<!-- fallback rule --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 
</xsl:stylesheet> 

Es gibt zwei schwierige Punkte. Zunächst benötigt eine CALS-Tabelle ein tgroup/@ cols Attribut, das die Anzahl der Spalten enthält. Also müssen wir die maximale Anzahl von Zellen in einer Zeile in der XHTML-Tabelle finden - aber wir müssen colspan Deklarationen beachten, so dass eine Zelle mit colspan > 1 die richtige Anzahl von Spalten erstellt! Die erste Vorlage in meinem Stylesheet macht genau das, basierend auf der Antwort von @Tim C auf die max cells per row problem.

Ein weiteres Problem besteht darin, dass für mehrspaltige Zellen XHTML sagt „diese Zelle 3 Spalten breit“ (colspan = „3“), während CALS wird sagen: „diese Zelle beginnt in Spalte 2 und endet in Spalte 4“ (namest = "2" nameend = "4"). Diese Umwandlung erfolgt in der zweiten Vorlage im Stylesheet.

Der Rest ist in der Tat ziemlich einfach. Das Stylesheet behandelt keine Details wie das Ändern von style = "width: 50%" in width = "50%" usw. aber das sind relativ häufige Probleme, glaube ich.

Answer 2

Obwohl ich das nicht die besondere Schwierigkeit verstehen, gegoogelt ich einige:

• Stylesheet for converting XHTML tables to CALS

Answer 3

Ich weiß, dass es 4 Jahre später, aber für jemanden, der über Posting kann kommen:

ISOSTS XHTML table to CALS conversion