Wie führe ich eine Zeile mehrmals mit Windows Batch-Datei?

Question

Unten ist meine Anforderung.

@echo off 
cls 
Set Sleep=0 
:start 
echo This is a loop 
xx.exe yyyyy.dll /p:InputDataSource=Table:table.xml 
Set /A Sleep+=1 
echo DisplayingSleepvalue 
echo %Sleep% 
goto start 

Hier möchte ich xx.exe yyyyy.dll /p:InputDataSource=Table:table.xml diese Zeile für 30 Mal auszuführen .... Könnte jemand bitte mir auf diesem helfen.

Danke,
Manasa

Answer 1

Versuchen Sie, diese Art und Weise: -

@echo off 
cls 
Set Sleep=0 
:start 
if %Sleep% == 30 (goto end) 
xx.exe yyyyy.dll /p:InputDataSource=Table:table.xml 
echo This is a loop 
Set /A Sleep+=1 
echo %Sleep% 
goto start 
:end 
echo "am 30 now" 
pause 

Answer 2

mit dem for Befehl Versuchen.

Answer 3

Sie können eine GOTO-Schleife mit einem inkrementierenden Zähler verwenden, aber eine FOR/L-Schleife ist viel effizienter.

for /l %%N in (1 1 30) do someCommand 

Studie der Dokumentation von HELP FOR oder FOR /? von der Kommandozeile eintippen.

Wenn Sie den gesamten Codeblock wiederholen möchten, schließen Sie den Block in Klammern ein. Sie können die Variable FOR %% N anstelle der Variablen Sleep verwenden.

@echo off 
cls 
for /l %%N in (1 1 30) do (
    echo This is a loop 
    xx.exe yyyyy.dll /p:InputDataSource=Table:table.xml 
    echo DisplayingSleepvalue 
    echo %%N 
) 

Es ist nicht mit Ihrem Beispiel benötigt, aber wenn Sie eine Umgebungsvariable in einer Schleife manipulieren wollen, dann müssen Sie verzögerten Expansion verwenden. Die normale Erweiterung %sleep% wird nur einmal erweitert, wenn die gesamte Schleife geparst wird, während Sie den Wert !sleep! zur Ausführungszeit für jede Schleifeniteration erweitern müssen. Die verzögerte Erweiterung muss aktiviert sein, bevor sie verwendet werden kann.

@echo off 
setlocal enableDelayedExpansion 
cls 
set sleep=0 
for /l %%N in (1 1 30) do (
    echo This is a loop 
    xx.exe yyyyy.dll /p:InputDataSource=Table:table.xml 
    set /a sleep+=1 
    echo DisplayingSleepvalue 
    echo !sleep! 
) 

Answer 4

Youve die Schleife bekam, nur einige mathematische hinzufügen.

Dies erhöht den Zähler jedes Mal, wenn der Befehl ausgeführt wird, und wenn es 30 Mal ausgeführt wurde, wird das Programm beendet.