AS3 - Variable ändern und Werte an den Listener übergeben

Question

Ich habe den folgenden Code von einer anderen Frage auf SO, um den sich ändernden Wert eines Zählers zu verfolgen.

package com.my.functions 
{ 
    import flash.events.Event; 
    import flash.events.EventDispatcher; 

    public class counterWithListener extends EventDispatcher 
    { 

     public static const VALUE_CHANGED:String = 'counter_changed'; 
     private var _counter:Number = 0; 

     public function counterWithListener() { } 

     public function set counter(value:Number):void 
     { 
      _counter = value; 
      this.dispatchEvent(new Event(counterWithListener.VALUE_CHANGED)); 

     } 

    } 

} 

Was würde ich tun, um den Wert des Zählers übergeben, bevor ich es geändert sowie der neue Wert für den Hörer so kann ich entscheiden, ob der neue Wert gültig ist.

Answer 1

Sie ein benutzerdefiniertes Ereignis erstellen möchten:

package 
{ 
    import flash.events.Event; 

    public class CounterEvent extends Event 
    { 
     public static const VALUE_CHANGED:String = 'valueChanged'; 

     public var before:int; 
     public var after:int; 

     public function CounterEvent(type:String, before:int, after:int) 
     { 
       this.after = after; 
       this.before = before; 

       //bubbles and cancellable set to false by default 
       //this is just my preference 
       super(type, false, false); 
     } 

     override public function clone() : Event 
     { 
       return new CounterEvent(this.type, this.before, this.after); 
     } 
    } 
} 

Dies wird Ihren obigen Code ändern:

package com.my.functions 
{ 
    import CounterEvent; 
    import flash.events.EventDispatcher; 

    public class counterWithListener extends EventDispatcher 
    { 
     private var _counter:Number = 0; 

     public function counterWithListener() { } 

     public function set counter(value:Number):void 
     { 
       this.dispatchEvent(new CounterEvent(CounterEvent.VALUE_CHANGED, _counter, value)); 
       _counter = value; 
     } 

    } 

}