Berechnung in Excel Zelle beim Verlassen der Zelle

Question

Ich arbeite an Excel-2010 und Excel-2013. Ich möchte etwas wie unten tun:

Unabhängig von der Nummer, die ich in Zelle eingeben, muss diese Nummer durch 60 geteilt werden und das Ergebnis sollte in der gleichen Zelle gedruckt werden, indem Sie TAB drücken. Wenn ich zu dieser Zelle zurückkomme, sollte die eingegebene Nummer angezeigt werden, nicht das Ergebnis der Berechnung.

Ich weiß nicht viel über die Programmierung in Excel. Ich kann die meisten Websites aufgrund der Sicherheitsrichtlinien des Unternehmens nicht öffnen.

Kann mir bitte jemand dabei helfen!

Answer 1

Bitte verwenden Sie diesen Code. Sie sollten diesen Code in Ihre Worksheet module, nicht Regular module einfügen. Passen Sie dann bitte Range("A1:A100") an, in welchen Zahlen geteilt werden soll.

Private Sub Worksheet_Change(ByVal Target As Range) 
Dim DivRg As Range 
Set DivRg = Range("A1:A100") 
Set DivRg = Application.Intersect(Target, DivRg) 

If DivRg Is Nothing Or Target.Cells.Count > 1 Then Exit Sub 

Application.EnableEvents = False 
Target = Target/60 
Target.Offset(0, 5).Value = 1 
Application.EnableEvents = True 

Set DivRg = Nothing 

End Sub 


Private Sub Worksheet_SelectionChange(ByVal Target As Range) 
Dim DivRg As Range 

Set DivRg = Range("A1:A100") 
Set DivRg = Application.Intersect(Target, DivRg) 

If DivRg Is Nothing Or Target.Cells.Count > 1 Then Exit Sub 

Application.EnableEvents = False 
If Target.Offset(0, 5).Value = 1 Then 
Target = Target * 60 
Target.Offset(0, 5).Value = 0 
End If 
Application.EnableEvents = True 

Set DivRg = Nothing 
End Sub 

Ihre Aufgabe zu erfüllen, können Sie eine Helfer-Säule benötigt (ich wählte Spalte F), aber Sie können jede Spalte wählen und diesen Teil des Codes ändern Target.Offset(0, 5).Value diese Spalte zu adressieren. Wenn die Helperspalte beispielsweise Spalte E sein soll, verwenden Sie diesen Code Target.Offset(0, 4).Value. Stellen Sie sicher, dass Sie diesen Code in allen 3 Teilen von Subs ersetzen.