Variable enthält dieselben Werte (VBA)

Question

Um eine Mailing-Liste zu generieren, habe ich erkannt, dass in meiner Variablen "To" die gleichen Werte test@test.com enthält. Die Mailingliste wurde in Visual Basic für Applikationen (VBA) definiert. Nun, ich überlege mir, wie ich eine zu überprüfende Aussage definieren könnte, wenn die Variable die gleichen Werte hat und dann alle Duplikate trimmt. Das heißt, ich brauche die Variable nur einmal in der Mailingliste.

Zum Beispiel:

Dim objMail As Object 
Dim objOutlook As Object 
Set objOutlook = CreateObject("Outlook.Application") 
Set objMail = objOutlook.CreateItem(0) 

With objMail 
    .To = test@test.com; name1@test.com; name2@test.com; name3@test.com; test@test.com; name4@test.com 
    ... 
End With 

Hat jemand eine Idee?

Answer 1

könnten Sie das Wörterbuch verwenden, um die Duplikate zu entfernen:

Sub Test() 

    Dim EmailAddresses As String 

    EmailAddresses = "test@test.com; name1@test.com; name2@test.com; name3@test.com; test@test.com; name4@test.com" 
    EmailAddresses = RemoveDuplicates(EmailAddresses) 

    Debug.Print EmailAddresses 

End Sub 

Public Function RemoveDuplicates(sTo As String) As String 

    Dim dict As Object 
    Dim vEmails As Variant 
    Dim x As Long 
    Dim sTemp As String 

    vEmails = Split(Replace(sTo, " ", ""), ";") 
    If UBound(vEmails) > 0 Then 
     'Remove duplicates. 
     Set dict = CreateObject("Scripting.Dictionary") 
     For x = LBound(vEmails) To UBound(vEmails) 
      If Not dict.exists(vEmails(x)) Then 
       dict.Add vEmails(x), 1 
       sTemp = sTemp & vEmails(x) & ";" 
      End If 
     Next x 
     sTemp = Left(sTemp, Len(sTemp) - 1) 'Remove the final ; 
     RemoveDuplicates = sTemp 
    Else 
     'There's only 1 address. 
     RemoveDuplicates = sTo 
    End If 

End Function 

Die oben tatsächlich ein paar Möglichkeiten, vereinfacht werden kann, auch wenn das Ihre Präferenz ist.

1. Für einfache Entdupping wie diese, keine Notwendigkeit, die zu verwenden. Exists Methode oder die .Add Methode, weil Wörterbuch Elemente träge erstellt werden. Dies bedeutet, dass so einfach auf ein Objekt Bezug genommen wird, wenn es nicht existiert, oder es überschreiben, wenn dies der Fall ist.
2. Anstatt die Zeichenfolge manuell parallel zum Wörterbuch zu erstellen, können Sie Join auf die Keys des Dict funktionieren.

Hier ist die überarbeitete Fassung:

Public Function RemoveDuplicates2(sTo As String) As String 
    Dim dict As Object 
    Dim vEmails As Variant 
    Dim x As Long 

    vEmails = Split(Replace(sTo, " ", ""), ";") 
    Set dict = CreateObject("Scripting.Dictionary") 
    For x = LBound(vEmails) To UBound(vEmails) 
     dict(vEmails(x)) = dict(vEmails(x)) 'Keep track of how many occurrences, in case you want to do something with it later 
    Next 

    RemoveDuplicates = Join(dict.Keys(), "; ") 

End Function