Lesen von Datei mit VBS und sagen Sie den Inhalt

Question

Ich arbeite an einem Projekt und ich schreibe in eine Datei aus einer anderen Datei, aber ich möchte eine .VBS-Datei es wie TTS sagen. hier ist der Code für das ... Aber

Dim message, sapi 
Set sapi=CreateObject("This Text") 
sapi.Speak message 

Und dann die Worte „Dieser Text“ wird der Lautsprecher kommen.

Aber ich will nicht die Worte „Dieser Text“ kommen, habe ich es die Worte in einer TXT-Datei (tts_text.txt)

So braucht es zum Lesen einer Textdatei sagen wollen und speichern Sie das in einer Variablen und dann sollten die TTS die Variable lesen und sagen.

Answer 1

verwenden lesen/lernen über die Objekte und ihre Fähigkeiten:

Option Explicit 
Dim goFS : Set goFS = CreateObject("Scripting.FileSystemObject") 
Dim goVC : Set goVC = CreateObject("SAPI.SpVoice") 
goVC.Speak goFS.OpenTextFile(WScript.ScriptFullName).ReadAll() 

Answer 2

Sie einen Versuch für dieses Vbscript Beispiel geben kann:

Option Explicit 
Dim Contents,File,message 
File = "c:\tts_text.txt" 
Contents = "It didn’t work after mass shootings at a nightclub in Orlando,"&_ 
"college campuses in Virginia and Oregon, a church in Charleston,"&_ 
"or at a movie theater and high school in Colorado."&_ 
"Or after two lawmakers survived assassination attempts." & vbcrlf &_ 
"But after a gunman killed 58 people and wounded more than 500 at a Las Vegas concert," & vbcrlf &_ 
"Democrats are going to try again to revamp the nation’s gun laws." 
' We write this contents to the file 
WriteTextFile Contents, file, 0 
' We read the file contents and we store it into a variable message 
message = ReadFileText(File) 
' Now we can speak this message with SAPI object 
Speak_from_File message 
'********************************************************** 
Sub Speak_from_File(message) 
Dim Voice 
Set Voice = CreateObject("SAPI.SpVoice") 
Voice.Volume = 100 
Voice.Rate = 0 
Voice.Speak message 
End Sub 
'********************************************************** 
Sub WriteTextFile(sContent, sPath, lFormat) 
'lFormat -2 - System default, -1 - Unicode, 0 - ASCII 
With CreateObject("Scripting.FileSystemObject").OpenTextFile(sPath,2,True,lFormat) 
    .WriteLine sContent 
    .Close 
End With 
End Sub 
'********************************************************** 
Function ReadFileText(sFile) 
    Dim objFSO,oTS,sText 
    Set objFSO = CreateObject("Scripting.FileSystemObject") 
    Set oTS = objFSO.OpenTextFile(sFile,1) 
    sText = oTS.ReadAll 
    oTS.close 
    set oTS = nothing 
    Set objFSO = nothing 
    ReadFileText = sText 
End Function 
'**********************************************************