Länge geordnete Untergruppen?

Question

Ich versuche, einen Code zu erstellen, der alle Teilmengen eines Satzes in der Reihenfolge generiert. Das heißt, sollte

X = []; 
X = [1]; 
X = [2]; 
X = [3]; 
X = [1,2]; 
X = [1,3]; 
X = [2,3]; 
X = [1,2,3]. 

Die innere Ordnung nicht so wichtig ist, nur erzeugen subset([1,2,3], X) Aufruf, dass die kleinsten Untergruppen aufgeführt sind erste (dh ist mir egal, wenn [2,3] vor [1 kommt , 2], nur dass 1, [2] und [3] sind vor [2,3]).

-

Ich habe bisher zwei Ansätze ausprobiert. Zuerst habe ich versucht, das Prädikat selbst zu machen ...

subset([], []). 
subset(List, []). 
subset(List, [N]) :- 
    member(N, List). 

subset(List, [N|Rest]) :- 
    !, 
    nth0(I, List, N), 
    findall(E, (nth0(J, List, E), J > I), NewList), 
    subset2(NewList, Rest). 

... aber es kommt nicht einmal annähernd so wie geplant. Zweitens habe ich versucht, das powerset (mit this subset predicate) und die Bestellung mit list_to_ord_set/2, aber ich konnte es auch nicht funktionieren.

Hilfe?

Answer 1

ich nicht so elegante Lösung gefunden habe ... erfordert es einen Schnitt und einige builtins

subset(Xs, Ys) :- 
    length(Xs, L), 
    between(0, L, N), 
    length(Ys, N), 
    assign(Xs, Ys). 

assign(_, []) :- !. 
assign([X|Xs], [X|Ys]) :- 
    assign(Xs, Ys). 
assign([_|Xs], Ys) :- 
    assign(Xs, Ys). 

wie @Fatalize erwähnt, können wir den Schnitt vermeiden, nur die leere Liste zwingt auf erstes Argument von 1^Klausel:

assign([], []). 
assign([X|Xs], [X|Ys]) :- 
    assign(Xs, Ys). 
assign([_|Xs], Ys) :- 
    assign(Xs, Ys). 

vermieden I 2^3^Klauseln zu tauschen, so dass die 'natürliche' Ordnung noch schön

Answer 2

immer auch mit DCG notation betrachten erhalten wHE n Listen beschreiben.

Zum Beispiel:

list_sublist(Ls0, Ls) :- 
     same_length(Ls0, Ls1), 
     append(Ls, _, Ls1), 
     phrase(sublist(Ls0), Ls). 

sublist([])  --> []. 
sublist([L|Ls]) --> ([] ; [L]), sublist(Ls). 

Beispielabfrage:

?- list_sublist([a,b,c], Ls). 
Ls = [] ; 
Ls = [c] ; 
Ls = [b] ; 
Ls = [a] ; 
Ls = [b, c] ; 
Ls = [a, c] ; 
Ls = [a, b] ; 
Ls = [a, b, c] ; 
false. 

Ein weiteres Beispiel:

?- list_sublist(Ls, [b,c]). 
Ls = [b, c] ; 
Ls = [_G511, b, c] ; 
Ls = [b, _G514, c] ; 
Ls = [b, c, _G517] ; 
etc. 

allgemeinsten Fall:

?- list_sublist(Xs, Ys). 
Xs = Ys, Ys = [] ; 
Xs = [_G513], 
Ys = [] ; 
Xs = Ys, Ys = [_G513] 
Xs = [_G513, _G516], 
Ys = [] ; 
etc.