Wie macht man die stille Installation mit InnoSetup?

Question

Ich muss die automatische Installation für meine Anwendung ohne nächsten, nächsten Installationsassistenten starten. Bitte helfen Sie mir.

Answer 1

Richtige Weg, um das Setup im Silent-Modus laufen soll, und immer mit /SILENT Kommandozeilenparameter werden ausgeführt wird. Zum Beispiel so:

setup.exe /SILENT 

Nachdem wir Ihre Anforderung in den Kommentaren geklärt Ich sehe, dass Sie tatsächlich ein Setup aufbauen wollen, die im Silent-Modus ohne die genannten Befehlszeilenparameter ausgeführt wird. Derzeit gibt es keine integrierte Möglichkeit, dem Compiler mitzuteilen, dass Sie eine unbeaufsichtigte Installation erstellen möchten, daher müssen wir dies umgehen, indem Sie das Setup mit dem Befehlszeilenparameter /SILENT erneut ausführen, wenn das Setup initialisiert wird.

Das folgende Skript zeigt diese Abhilfe:

[Setup] 
AppName=My Program 
AppVersion=1.5 
DefaultDirName={pf}\My Program 

[Code] 
#ifdef UNICODE 
    #define AW "W" 
#else 
    #define AW "A" 
#endif 
type 
    HINSTANCE = THandle; 

function ShellExecute(hwnd: HWND; lpOperation: string; lpFile: string; 
    lpParameters: string; lpDirectory: string; nShowCmd: Integer): HINSTANCE; 
    external 'ShellExecute{#AW}@shell32.dll stdcall'; 

function InitializeSetup: Boolean; 
begin 
    // if this instance of the setup is not silent which is by running 
    // setup binary without /SILENT parameter, stop the initialization 
    Result := WizardSilent; 
    // if this instance is not silent, then... 
    if not Result then 
    begin 
    // re-run the setup with /SILENT parameter; because executing of 
    // the setup loader is not possible with ShellExec function, we 
    // need to use a WinAPI workaround 
    if ShellExecute(0, '', ExpandConstant('{srcexe}'), '/SILENT', '', 
     SW_SHOW) <= 32 
    then 
     // if re-running this setup to silent mode failed, let's allow 
     // this non-silent setup to be run 
     Result := True; 
    end; 
end;