Wie kann ich mit Delphi testen, ob ein Verzeichnis beschreibbar ist?

Question

Derzeit verwende ich diese Funktion, basierend auf Code JCL, der gut arbeitet:

function IsDirectoryWriteable(const AName: string): Boolean; 
var 
    FileName: PWideChar; 
    H: THandle; 
begin 
    FileName := PWideChar(IncludeTrailingPathDelimiter(AName) + 'chk.tmp'); 

    H := CreateFile(FileName, GENERIC_READ or GENERIC_WRITE, 0, nil, 
    CREATE_NEW, FILE_ATTRIBUTE_TEMPORARY or FILE_FLAG_DELETE_ON_CLOSE, 0); 

    Result := H <> INVALID_HANDLE_VALUE; 

    DeleteFile(FileName); 
end; 

Gibt es etwas, was ich mit den Flaggen verbessern könnte? Kann der Test durchgeführt werden, ohne tatsächlich eine Datei zu erstellen? Oder ist diese Funktionalität sogar bereits in einer der RTL- oder Jedi-Bibliotheken verfügbar?

Answer 1

Das Schreiben in das Verzeichnis ist der einfachste Weg, um festzustellen, ob das Verzeichnis beschreibbar ist. Es gibt zu viele Sicherheitsoptionen, die Sie einzeln überprüfen können, und selbst dann verpassen Sie möglicherweise etwas.

Sie müssen auch das geöffnete Handle vor dem Aufrufen von DeleteFile() schließen. Was Sie sowieso nicht tun müssen, da Sie das Flag FILE_FLAG_DELETE_ON_CLOSE verwenden.

BTW, es gibt einen kleinen Fehler in Ihrem Code. Sie erstellen einen temporären String und weisen ihn einem PWideChar zu, aber der String verlässt den Gültigkeitsbereich und gibt den Speicher frei, bevor der PWideChar tatsächlich verwendet wird. Ihre FileName-Variable sollte eine Zeichenfolge anstelle von PWideChar sein. Führen Sie die Typumwandlung beim Aufrufen von CreateFile() durch, nicht vorher.

Versuchen Sie folgendes:

function IsDirectoryWriteable(const AName: string): Boolean; 
var 
    FileName: String; 
    H: THandle; 
begin 
    FileName := IncludeTrailingPathDelimiter(AName) + 'chk.tmp'; 
    H := CreateFile(PChar(FileName), GENERIC_READ or GENERIC_WRITE, 0, nil, 
    CREATE_NEW, FILE_ATTRIBUTE_TEMPORARY or FILE_FLAG_DELETE_ON_CLOSE, 0); 
    Result := H <> INVALID_HANDLE_VALUE; 
    if Result then CloseHandle(H); 
end; 

Answer 2

Andreas ...

den Sicherheits-APIs Mit den effektiven Rechte für eine Datei erhalten/Verzeichnis ist ein Chaos PIA und einfach nicht zuverlässig. (I abgeladen alle meine Code zu tun, um für nur überprüfen, ob ich eine Datei im Verzeichnis schreiben konnte.)

Cf, http://www.ureader.com/msg/16591730.aspx

(Ich habe andere Refs., Aber ich bin ein neuer Benutzer und kann nur einen Link posten. Folgen Sie einfach den URLs im obigen Link.)

Answer 3

Sicherlich alles, was Sie tun müssen, um Ihre Zugriffsrechte auf das Verzeichnis überprüfen. Was ist mit dem ist falsch:

function IsDirectoryWriteable(aName : String); 
var 
    FileObject : TJwSecureFileObject; 
    DesiredAccess: ACCESS_MASK; 
begin 
    DesiredAccess := FILE_GENERIC_WRITE; 
    FileObject := TJwSecureFileObject.Create(aName); 
    try 
    result := FileObject.AccessCheck(DesiredAccess); 
    finally 
    FileObject.Free; 
    end; 
end; 

Answer 4

Hier ist meine Version GetTempFileName verwendet, die eine einzigartige temporäre Datei im Zielverzeichnis zu erstellen versucht:

function IsDirecoryWriteable(const AName: string): Boolean; 
var 
    TempFileName: array[0..MAX_PATH] of Char; 
begin 
    { attempt to create a temp file in the directory } 
    Result := GetTempFileName(PChar(AName), '$', 0, TempFileName) <> 0; 
    if Result then 
    { clean up } 
    Result := DeleteFile(TempFileName); 
end;