Capture HTA Fenster schließen Ereignis mit VBScript

Ich habe mit der Verwendung eines HTA als ein Mittel zum Kennenlernen von HTML gespielt. Ich habe Code hinzugefügt, um alle Fenster zu minimieren, wenn das hta-Fenster geöffnet wurde, aber ich konnte nicht herausfinden, wie alle Fenster wiederhergestellt werden, wenn das hta geschlossen wird. Irgendwelche Vorschläge? (Die meisten der Code ist hier von einer Seite, die ich auf HTAs las)Capture HTA Fenster schließen Ereignis mit VBScript

<html> 
<head> 
<title>processes</title> 
<HTA:APPLICATION 
    APPLICATIONNAME="processes" 
    ID="processes" 
    VERSION="1.0"/> 
</head> 

<script language="VBScript"> 

Sub Window_OnLoad 
    Set objShell = CreateObject("shell.application") 
    objShell.ToggleDesktop 
    Dim width,height 
    width=600 
    height=800 
    Set oShell = CreateObject("wscript.shell") 
    oShell.SendKeys "% r" 
    self.ResizeTo width,height 
    self.MoveTo (screen.AvailWidth-width)/2,(screen.AvailHeight-height)/2 

End Sub 


    Sub GetProcesses 

     strComputer = "." 

     Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2") 
     Set colProcesses = objWMIService.ExecQuery("Select * from Win32_Process") 

     For Each objProcess in colProcesses 
      strHTML = strHTML & objProcess.Name & " -- " & objProcess.ProcessID & "<br>" 
     Next 

     DataArea.InnerHTML = strHTML 

    End Sub 

</script> 

<body bgcolor="white"> 

<input type="button" value="Processes" name="run_button" onClick="GetProcesses"> 
<span id = "DataArea"></span> 
</body> 
</html>

Quelle

2016-12-21 Adam Turner

Verwenden window_unload

<html> 
    <head> 
    <title>processes</title> 
    <HTA:APPLICATION 
     APPLICATIONNAME="processes" 
     ID="processes" 
     VERSION="1.0"/> 
    </head> 

    <script language="VBScript"> 

    Sub Window_OnLoad 
     Set objShell = CreateObject("shell.application") 
     objShell.MinimizeAll 
     Set objShell = Nothing 
     Dim width,height 
     width=600 
     height=800 
     Set oShell = CreateObject("wscript.shell") 
     oShell.SendKeys "% r" 
     self.ResizeTo width,height 
     self.MoveTo (screen.AvailWidth-width)/2,(screen.AvailHeight-height)/2 

    End Sub 

    sub Window_onUnload 
     Set objShell = CreateObject("shell.application") 
     objShell.UndoMinimizeALL 
     Set objShell = Nothing 
    end sub 

    Sub GetProcesses 

     strComputer = "." 

     Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2") 
     Set colProcesses = objWMIService.ExecQuery("Select * from Win32_Process") 

     For Each objProcess in colProcesses 
      strHTML = strHTML & objProcess.Name & " -- " & objProcess.ProcessID & "<br>" 
     Next 

     DataArea.InnerHTML = strHTML 

    End Sub 

    </script> 

    <body bgcolor="white"> 

    <input type="button" value="Processes" name="run_button" onClick="GetProcesses"> 
    <span id = "DataArea"></span> 
    </body> 
    </html>

Quelle

2016-12-21 18:05:16 Barney

Capture HTA Fenster schließen Ereignis mit VBScript

Antwort

Verwandte Themen