Einfachste Möglichkeit, Vorkommen von zwei Strings in Vim zu tauschen?

Question

Was ist der einfachste Weg, um alle Vorkommen von string_a durch string_b zu ersetzen und gleichzeitig alles, was bereits string_b war, in string_a zu ändern? Meine aktuelle Methode ist wie folgt:

:s/string_a/string_c/g 
:s/string_b/string_a/g 
:s/string_c/string_b/g 

Obwohl dies funktioniert, erfordert es zusätzliche Typisierung und scheint ineffizient. Weiß jemand einen besseren Weg, dies zu tun?

Answer 1

ich es so tun würde:

:%s/\v(foo|bar)/\={'foo':'bar','bar':'foo'}[submatch(0)]/g 

Aber das ist zu viel schreiben, würde ich dies so tun:

function! Mirror(dict) 
    for [key, value] in items(a:dict) 
     let a:dict[value] = key 
    endfor 
    return a:dict 
endfunction 

function! S(number) 
    return submatch(a:number) 
endfunction 

:%s/\v(foo|bar)/\=Mirror({'foo':'bar'})[S(0)]/g 

Aber das erfordert noch zweimal foo und bar eingeben, so dass ich so etwas tun würde:

function! SwapWords(dict, ...) 
    let words = keys(a:dict) + values(a:dict) 
    let words = map(words, 'escape(v:val, "|")') 
    if(a:0 == 1) 
     let delimiter = a:1 
    else 
     let delimiter = '/' 
    endif 
    let pattern = '\v(' . join(words, '|') . ')' 
    exe '%s' . delimiter . pattern . delimiter 
     \ . '\=' . string(Mirror(a:dict)) . '[S(0)]' 
     \ . delimiter . 'g' 
endfunction 

:call SwapWords({'foo':'bar'}) 

Wenn einer Ihrer Worte ein / enthält, müssen Sie in einem Begrenzer passieren die Sie weiß keiner Ihrer Worte enthält, .EG

:call SwapWords({'foo/bar':'foo/baz'}, '@') 

Dies hat auch den Vorteil, in der Lage, mehrere Paare von Wörtern auf einmal zu tauschen.

:call SwapWords({'foo':'bar', 'baz':'quux'}) 

Answer 2

Sie können es mit einem einzigen Befehl tun, wie unten in meinem Code gezeigt:

:%s/\<\(string_a\|string_b\)\>/\=strpart("string_bstring_a", 8 * ("string_b" == submatch(0)), 8)/g 

Update: der Herausgeber hier in Stackoverflow ist mich verrückt, weil es das Entfernen backslahes hält ...

Answer 3

Sie können dies leicht mit Tim Popes Abolish Plugin

:%S/{transmit,receive}/{receive,transmit} 

Answer 4

Die swapstrings plugin einen handlichen Befehl hierfür lauten:

:SwapStrings string_a string_b 

Answer 5

Hier ist, wie ich tausche zwei Worte skip & limit .

%s/skip/xxxxx/g|%s/limit/skip/g|%s/xxxxx/limit/g

Ziemlich sicher, dass jemand sie in einen kürzeren Befehl drehen könnte, die zwei Argumente akzeptiert.