Kombinieren von Prädikaten in F #

Question

Gibt es eine Standardmethode zum logischen Kombinieren von Prädikaten in F #? Zum Beispiel lassen Sie uns sagen, ich habe isCar x und isBlue x dann etwas, das ich will, das gibt mir:

let isBlueCar x = isCar x && isBlue x 

Aber irgendeine Art von Zusammensetzung, anstatt Aufruf, vielleicht wie:

let isBlueCar x = isCar && isBlue 

Vorzugsweise dass etwas wäre in der Lage, eine große/willkürliche Anzahl von Prädikaten zu akzeptieren.

Answer 1

Sie könnten einen Kombinator definieren.

let (<&>) f g = (fun x -> f x && g x) 

dann tun

let isBlueCar = isCar <&> isBlue 

Answer 2

Ist das wonach Sie suchen?

> let (&&<) a b x = a x && b x 

val (&&<) : ('a -> bool) -> ('a -> bool) -> 'a -> bool 

> let isBlueCar = isCar &&< isBlue 

val isBlueCar : (int -> bool) 

Answer 3

Sie so etwas wie das folgende tun könnte:

let predicates = [isCar; isBlue] 
let isBlueCar x = predicates |> List.forall (fun predicate -> predicate x) 

Allgemeiner:

let combinePredicates predicates = 
    fun x -> predicates |> List.forall (fun predicate -> predicate x) 

let isBlueCar = combinePredicates [isCar;isBlue] 

Answer 4

let meetsAll preds = preds |> Seq.fold (fun p q x -> p x && q x) (fun _ -> true) 
// or  let meetsAll preds x = preds |> Seq.forall (fun p -> p x) 

wie in

let isEven x = x%2 = 0 
let isDiv5 x = x%5 = 0 
let isDiv7 x = x%7 = 0 

let div257 = meetsAll [isEven; isDiv5; isDiv7] 

for i in 1..100 do 
    if div257 i then 
     printfn "%d" i 

Es gibt keine Standard-Library-Funktion für sie, aber es gibt eine Fülle von Einzeiler Sie selbst definieren können, wie hier durch die Antworten belegt.