Bearbeiten VBA zum Einfügen mehrerer Blätter als Werte in neue Arbeitsmappe

Question

Der Code von this forum ist, was ich als Ausgangspunkt verwendet habe. Ich versuche, es zu ändern, um mehrere Blätter zu kopieren und sie alle als Werte anstelle von nur einem Blatt einzufügen.

Ich kopierte mehrere Blätter mit worksheets(array(1,2,3)).copy. Ich denke, das Problem ist With ActiveSheet.UsedRange, weil es nur das erste Blatt als Werte ersetzt und die restlichen Blätter als Formeln belassen.

Was muss ich ändern, damit alle Blätter als Werte eingefügt werden?

Private Sub Workbook_BeforeClose(Cancel As Boolean) 
    Application.DisplayAlerts = False 
    Worksheets(Array("Sheet 1","Sheet 2","Sheet 3").Copy 
    With ActiveSheet.UsedRange 
     .Value = .Value 
    End With 
    Set wbNew = ActiveWorkbook 
    wbNew.SaveAs "L:\Performance Data\UK Sales\Sales (Latest).xlsx" 
    wbNew.Close True 
    Application.DisplayAlerts = True 
End Sub 

Answer 1

Sie müssen sich durch die Blätter in einer Schleife:

Dim ws As Worksheet 

For Each ws In ActiveWorkbook.Worksheets 
    ws.UsedRange.Value = ws.UsedRange.Value 
Next ws 

Also, mit Ihrem Code, können Sie es wie dies tun könnte:

Private Sub Workbook_BeforeClose(Cancel As Boolean) 
Dim wbOld As Workbook, wbNew As Workbook 
Dim ws As Worksheet, delWS As Worksheet 
Dim i  As Long, lastRow As Long, lastCol As Long 
Dim shts() As Variant 
Dim rng As Range 

Application.ScreenUpdating = False 
Application.DisplayAlerts = False 

Set wbOld = ActiveWorkbook 

shts() = Array("Sheet 1", "Sheet 2", "Sheet 3") 
Set wbNew = Workbooks.Add 
Set delWS = ActiveSheet 
wbOld.Worksheets(Array("Sheet 1", "Sheet 2", "Sheet 3")).Copy wbNew.Worksheets(1) 
delWS.Delete 

For i = LBound(shts) To UBound(shts) 
    With wbNew.Worksheets(shts(i)) 
     lastRow = .Cells(.Rows.Count, 1).End(xlUp).Row 
     lastCol = .Cells(1, .Columns.Count).End(xlToLeft).Column 
     Set rng = .Range(.Cells(1, 1), .Cells(lastRow, lastCol)) 
     rng.Value = rng.Value 
    End With 
Next i 

wbNew.SaveAs "L:\Performance Data\UK Sales\Sales (Latest).xlsx" 
wbNew.Close True 

Application.DisplayAlerts = True 
Application.ScreenUpdating = True 
End Sub 

Hinweis: Ich bin nicht sicher, ob die Arbeitsmappe Sie möchten die Werte einfügen. Wie oben beschrieben, geschieht dies in der COPIED-Arbeitsmappe, nicht im Original.